Puppet Class: kubeinstall::kubeadm::config

Defined in:
manifests/kubeadm/config.pp

Summary

A short summary of the purpose of this class

Overview

A description of what this class does

Examples:

include kubeinstall::kubeadm::config

Parameters:

  • cri_socket (Stdlib::Unixpath) (defaults to: $kubeinstall::cri_socket) —

    CRISocket is used to retrieve container runtime info. This information will be annotated to the Node API object, for later re-use

  • service_node_port_range (Kubeinstall::Range5X) (defaults to: $kubeinstall::service_node_port_range) —

    A port range to reserve for services with NodePort visibility. Example: ‘30000-32767’. Inclusive at both ends of the range.

  • topolvm_scheduler (Boolean) (defaults to: $kubeinstall::topolvm_scheduler) —

    Whether to manage TopoLVM scheduler setup

  • bootstrap_token (Optional[Kubeinstall::Token]) (defaults to: undef)
  • token_ttl (String[2]) (defaults to: '24h0m0s')
  • apiserver_advertise_address (Kubeinstall::Address) (defaults to: $kubeinstall::apiserver_advertise_address)
  • apiserver_bind_port (Integer) (defaults to: $kubeinstall::apiserver_bind_port)
  • node_name (Stdlib::Fqdn) (defaults to: $kubeinstall::node_name)
  • cluster_name (String) (defaults to: $kubeinstall::cluster_name)
  • kubernetes_version (Kubeinstall::VersionPrefix) (defaults to: $kubeinstall::kubernetes_version)
  • service_dns_domain (Stdlib::Fqdn) (defaults to: $kubeinstall::service_dns_domain)
  • service_cidr (Stdlib::IP::Address) (defaults to: $kubeinstall::service_cidr)
  • pod_network_cidr (Stdlib::IP::Address) (defaults to: $kubeinstall::pod_network_cidr)
  • control_plane_endpoint (Optional[Kubeinstall::Address]) (defaults to: $kubeinstall::control_plane_endpoint)
  • cgroup_driver (Kubeinstall::CgroupDriver) (defaults to: $kubeinstall::cgroup_driver) 


19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
 
# File 'manifests/kubeadm/config.pp', line 19

class kubeinstall::kubeadm::config (
  Optional[Kubeinstall::Token] $bootstrap_token = undef,
  String[2] $token_ttl = '24h0m0s',
  Kubeinstall::Address $apiserver_advertise_address = $kubeinstall::apiserver_advertise_address,
  Integer $apiserver_bind_port = $kubeinstall::apiserver_bind_port,
  Stdlib::Fqdn $node_name = $kubeinstall::node_name,
  Stdlib::Unixpath $cri_socket = $kubeinstall::cri_socket,
  String $cluster_name = $kubeinstall::cluster_name,
  Kubeinstall::VersionPrefix $kubernetes_version = $kubeinstall::kubernetes_version,
  Stdlib::Fqdn $service_dns_domain = $kubeinstall::service_dns_domain,
  Stdlib::IP::Address $service_cidr = $kubeinstall::service_cidr,
  Stdlib::IP::Address $pod_network_cidr = $kubeinstall::pod_network_cidr,
  Kubeinstall::Range5X $service_node_port_range = $kubeinstall::service_node_port_range,
  Optional[Kubeinstall::Address] $control_plane_endpoint = $kubeinstall::control_plane_endpoint,
  Kubeinstall::CgroupDriver $cgroup_driver = $kubeinstall::cgroup_driver,
  Boolean $topolvm_scheduler = $kubeinstall::topolvm_scheduler,
) {
  unless $token_ttl =~ Kubeinstall::TokenTTL {
    fail("parameter 'token_ttl' expects a match for Pattern[/^([0-9]+h)?([0-5]?[0-9]m)?([0-5]?[0-9]s)?$/], got '${token_ttl}'")
  }

  [$svc_port_min, $svc_port_max] = split($service_node_port_range, '-')
  if $svc_port_min =~ Kubeinstall::Port and $svc_port_max =~ Kubeinstall::Port {
    if (0 + $svc_port_min) > (0 + $svc_port_max) {
      fail("parameter 'service_node_port_range' must be a valid port range (min < max)")
    }
  }
  else {
    fail("parameter 'service_node_port_range' must be a valid port range (min = 1, max = 65535)")
  }

  # it could be RPM package version
  $version_data = split($kubernetes_version, '[-]')
  $version = $version_data[0]

  # https://godoc.org/k8s.io/kubernetes/cmd/kubeadm/app/apis/kubeadm/v1beta2
  $init_header  = {
    'apiVersion' => 'kubeadm.k8s.io/v1beta3',
    'kind' => 'InitConfiguration',
  }

  if $bootstrap_token {
    $bootstrap_tokens = {
      'bootstrapTokens' => [
        {
          'groups' => ['system:bootstrappers:kubeadm:default-node-token'],
          'token'  => $bootstrap_token,
          'ttl'    => $token_ttl,
          'usages' => ['signing', 'authentication'],
        }
      ],
    }
  }
  else {
    $bootstrap_tokens = {}
  }

  $kubelet_extra_args = {
    # Flag --cgroup-driver has been deprecated, This parameter should be set via the config file specified by the Kubelet's --config flag
    # 'cgroup-driver' => $cgroup_driver,
  }

  $init_base = {
    'localAPIEndpoint' => {
      'advertiseAddress' => $apiserver_advertise_address,
      'bindPort'         => $apiserver_bind_port,
    },
    'nodeRegistration' => {
      'criSocket' => $cri_socket,
      'name'      => $node_name,
      'taints'    => [
        {
          'effect' => 'NoSchedule',
          'key'    => 'node-role.kubernetes.io/master',
        },
      ],
      'kubeletExtraArgs' => $kubelet_extra_args,
    },
  }

  $cluster_header = {
    'apiVersion' => 'kubeadm.k8s.io/v1beta3',
    'kind'       => 'ClusterConfiguration',
  }

  if $topolvm_scheduler {
    include kubeinstall::topolvm::scheduler

    # Configure kube-scheduler for new clusters
    # https://github.com/topolvm/topolvm/tree/main/deploy#for-new-clusters
    $cluster_scheduler = {
      'extraVolumes' => [
        {
          'name'      => 'config',
          'hostPath'  => $kubeinstall::topolvm::scheduler::path,
          'mountPath' => '/var/lib/scheduler',
          'readOnly'  => true,
        },
      ],
      'extraArgs'    => {
        'config' => '/var/lib/scheduler/scheduler-config.yaml',
      },
    }
  }
  else {
    $cluster_scheduler = {}
  }

  $cluster_base = {
    'apiServer'         => {
      'timeoutForControlPlane' => '4m0s',
      'extraArgs' => {
        'service-node-port-range' => $service_node_port_range,
      },
    },
    'certificatesDir'   => '/etc/kubernetes/pki',
    'clusterName'       => $cluster_name,
    'controllerManager' => {},
    # See https://kubernetes.io/docs/reference/config-api/kubeadm-config.v1beta3/
    # The "ClusterConfiguration.DNS.Type" field has been removed since CoreDNS is the only supported DNS server type by kubeadm
    'dns'               => {
      # 'type' => 'CoreDNS',
    },
    'etcd'              => {
      'local' => {
        'dataDir' => '/var/lib/etcd',
      },
    },
    # See https://kubernetes.io/blog/2023/03/10/image-registry-redirect/
    'imageRepository'   => 'registry.k8s.io',
    'kubernetesVersion' => "v${version}",
    'networking'        => {
      'dnsDomain'     => $service_dns_domain,
      'serviceSubnet' => $service_cidr,
      'podSubnet'     => $pod_network_cidr,
    },
    'scheduler'         => $cluster_scheduler,
  }

  if $control_plane_endpoint {
    $cluster_control_plane_endpoint = {
      'controlPlaneEndpoint' => $control_plane_endpoint,
    }
  }
  else {
    $cluster_control_plane_endpoint = {}
  }

  $init_configuration = to_yaml($init_header + $bootstrap_tokens + $init_base)
  $cluster_configuration = to_yaml($cluster_header + $cluster_base + $cluster_control_plane_endpoint)

  file { '/etc/kubernetes/kubeadm-init.conf':
    ensure  => file,
    content => join([$init_configuration, $cluster_configuration], ''),
    mode    => '0600',
  }
}