Puppet Class: nagios::nrpe::client

Defined in:
manifests/nrpe/client.pp

Overview

Class: nagios::nrpe::client

Installs nrpe and ensures the service is up and running.

NB: the class name can be confusing. The idea is that leaf nodes are nagios “clients”, even if they run a service such as nrpe.

Example usage:

include nagios
include nagios::nrpe::client



13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
 
# File 'manifests/nrpe/client.pp', line 13

class nagios::nrpe::client {

  $package_name = $::osfamily ? {
    'Debian' => 'nagios-nrpe-server',
    'RedHat' => 'nrpe',
  }

  $service_name = $::osfamily ? {
    'Debian' => 'nagios-nrpe-server',
    'RedHat' => 'nrpe',
  }

  package { 'nrpe':
    ensure => present,
    name   => $package_name,
  }

  $nologin_path = $::osfamily ? {
    'Debian' => '/usr/sbin/nologin',
    'RedHat' => '/sbin/nologin',
  }

  user{ 'nrpe':
    ensure  => present,
    shell   => $nologin_path,
    require => Package['nrpe'],
  }

  if $::osfamily == 'RedHat' and $::operatingsystemmajrelease == '7' {
    $provider = 'redhat'
  } else {
    $provider = undef
  }

  if $::operatingsystem == 'Debian' and $::operatingsystemmajrelease == '6' {
    $hasstatus = false
  } else {
    $hasstatus = undef
  }

  service { 'nrpe':
    ensure    => running,
    provider  => $provider,
    hasstatus => $hasstatus,
    name      => $service_name,
    enable    => true,
    pattern   => '/usr/sbin/nrpe',
    require   => Package['nrpe'],
  }

  $module_path = get_module_path($module_name)
  augeas::lens { 'nrpe':
    ensure       => 'present',
    lens_content => file("${module_path}/files/nrpe.aug"),
    stock_since  => '1.1.0',
  }

}