Puppet Class: sssd::config

Defined in:
manifests/config.pp

Overview

Class: sssd::config

This class configures sssd. It is not intended to be called directly.



6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
 
# File 'manifests/config.pp', line 6

class sssd::config {

  if $caller_module_name != $module_name {
    fail("Use of private class ${name} by ${caller_module_name}")
  }

  if versioncmp($::operatingsystemrelease, '7.0') >= 0 {
    $_sys_source = 'puppet:///modules/sssd/system-auth.oddjob'
    $_pwauth_source = 'puppet:///modules/sssd/password-auth'
  } else {
    $_sys_source = 'puppet:///modules/sssd/system-auth'
    $_pwauth_source = 'puppet:///modules/sssd/password-auth.6'
  }

  file { '/etc/sssd/sssd.conf':
    ensure  => 'file',
    owner   => 'root',
    group   => 'root',
    mode    => '0600',
    content => template('sssd/sssd.conf.erb'),
  }

  file { '/etc/pam.d/password-auth':
    ensure => file,
    owner  => 'root',
    group  => 'root',
    mode   => '0444',
    source => $_pwauth_source,
  }

  file { '/etc/pam.d/system-auth':
    ensure => file,
    owner  => 'root',
    group  => 'root',
    mode   => '0444',
    source => $_sys_source,
  }

  if $sssd::manage_nsswitch {
    file { '/etc/nsswitch.conf':
      ensure => file,
      owner  => 'root',
      group  => 'root',
      mode   => '0444',
      source => 'puppet:///modules/sssd/nsswitch.conf',
    }
  }

  case $sssd::logsagent {
    'beaver': {
      beaver::stanza { '/var/log/sssd/sssd_LDAP.log':
        type => 'sssd',
        tags => ['sssd', 'ldap', $::disposition],
      }

      beaver::stanza { '/var/log/sssd/sssd.log':
        type => 'sssd',
        tags => ['sssd', $::disposition],
      }

      beaver::stanza { '/var/log/sssd/sssd_nss.log':
        type => 'sssd',
        tags => ['sssd', 'nss', $::disposition],
      }

      beaver::stanza { '/var/log/sssd/sssd_pam.log':
        type => 'sssd',
        tags => ['sssd', 'pam', $::disposition],
      }
    }
    default: {}
  }


}