Puppet Class: psick::admin::master

Defined in:
manifests/admin/master.pp

Summary

Manages admin configurations on admin master

Overview

Parameters:

  • ensure (Variant[Boolean,String]) (defaults to: 'present')
  • inventory_epp (Variant[Undef,String]) (defaults to: undef)
  • ssh_key (Variant[Undef,String]) (defaults to: undef)
  • manage (Boolean) (defaults to: $psick::manage)
  • noop_manage (Boolean) (defaults to: $psick::noop_manage)
  • noop_value (Boolean) (defaults to: $psick::noop_value)
[View source]

3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
 
# File 'manifests/admin/master.pp', line 3

class psick::admin::master (

  Variant[Boolean,String] $ensure        = 'present',

  Variant[Undef,String]   $inventory_epp = undef,
  Variant[Undef,String]   $ssh_key       = undef,

  Boolean          $manage               = $psick::manage,
  Boolean          $noop_manage          = $psick::noop_manage,
  Boolean          $noop_value           = $psick::noop_value,
) {
  if $manage {
    if $noop_manage {
      noop($noop_value)
    }
    include psick::admin

    if $psick::admin::keyshare_method == 'storeconfigs'
    and ($ssh_key or getvar('facts.admin_user_key')) {
      @@ssh_authorized_key { "admin_user_${psick::admin::user}_rsa-${facts['clientcert']}":
        ensure => $ensure,
        key    => pick($ssh_key,getvar('facts.admin_user_key')),
        user   => $psick::admin::user,
        type   => 'rsa',
        tag    => "admin_master_${psick::admin::master}",
      }
      Sshkey <<| tag == "admin_node_${psick::admin::master}_rsa" |>>
    }
  }
}