Puppet Class: jetty

Defined in:
manifests/init.pp

Overview

Class: jetty

This class installs and configure Jetty Web server.

Parameters:

$version

The version of Jetty to download.

$group

Group who own Jetty.

$user

User who own Jetty.

$home

Jetty home path.

$log

Jetty log path.

$tmp

Temp directory.

$java_properties

Java properties for the jvm.

$jetty_properties

Jetty properties.

$create_work_dir

If create ‘work’ directory.

$remove_demo_base

If remove ‘demo-base’ directory.

Requires:

Java

Sample Usage:

class {'jetty':
  version => 9.1.3.v20140225,
}

Authors

Gamaliel Sick

Copyright 2014 Gamaliel Sick, unless otherwise noted.

Parameters:

  • version (Any) (defaults to: hiera('jetty::version'))
  • group (Any) (defaults to: hiera('jetty::group', 'jetty'))
  • user (Any) (defaults to: hiera('jetty::user', 'jetty'))
  • home (Any) (defaults to: hiera('jetty::home', '/opt/jetty'))
  • log (Any) (defaults to: hiera('jetty::log', '/var/log/jetty'))
  • tmp (Any) (defaults to: hiera('jetty::tmp', '/tmp'))
  • java_properties (Any) (defaults to: hiera('jetty::java_properties', undef))
  • jetty_properties (Any) (defaults to: hiera('jetty::jetty_properties', {}))
  • create_work_dir (Any) (defaults to: hiera('jetty::create_work_dir', false))
  • remove_demo_base (Any) (defaults to: hiera('jetty::remove_demo_base', true)) 


45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
 
# File 'manifests/init.pp', line 45

class jetty(
  $version                = hiera('jetty::version'),
  $group                  = hiera('jetty::group', 'jetty'),
  $user                   = hiera('jetty::user', 'jetty'),
  $home                   = hiera('jetty::home', '/opt/jetty'),
  $log                    = hiera('jetty::log', '/var/log/jetty'),
  $tmp                    = hiera('jetty::tmp', '/tmp'),
  $java_properties        = hiera('jetty::java_properties', undef),
  $jetty_properties       = hiera('jetty::jetty_properties', {}),
  $create_work_dir        = hiera('jetty::create_work_dir', false),
  $remove_demo_base       = hiera('jetty::remove_demo_base', true),
) {

  $default_jetty_properties = {
    'JETTY_HOME' => $home,
    'JETTY_USER' => $user,
    'JETTY_PORT' => 8080,
    'JETTY_HOST' => '127.0.0.1',
    'JETTY_LOGS' => $log,
  }

  validate_hash($jetty_properties)
  $final_jetty_properties = merge($default_jetty_properties, $jetty_properties)

  require java

  singleton_packages('unzip', 'wget')

  group { 'jetty group':
    ensure => present,
    name   => $group,
  }

  user { 'jetty user':
    ensure     => present,
    name       => $user,
    groups     => $group,
    managehome => true,
    shell      => '/bin/bash',
    require    => Group['jetty group'],
  }

  exec { 'download jetty':
    cwd     => $tmp,
    path    => '/bin:/usr/bin',
    command => "wget http://repo1.maven.org/maven2/org/eclipse/jetty/jetty-distribution/${version}/jetty-distribution-${version}.zip",
    creates => "${tmp}/jetty-distribution-${version}.zip",
    notify  => Exec['unzip jetty'],
    require => Package['wget'],
  }

  exec { 'unzip jetty':
    cwd     => $tmp,
    path    => '/bin:/usr/bin',
    command => "unzip jetty-distribution-${version}.zip -d /opt",
    creates => "/opt/jetty-distribution-${version}",
    require => Package['unzip'],
  }

  file { 'jetty directory':
    ensure  => directory,
    path    => "/opt/jetty-distribution-${version}",
    owner   => $user,
    group   => $group,
    recurse => true,
    require => [User['jetty user'], Exec['unzip jetty']],
  }

  file { 'jetty home':
    ensure  => 'link',
    path    => $home,
    target  => "/opt/jetty-distribution-${version}",
    require => File['jetty directory'],
  }

  file { 'jetty init':
    ensure  => 'link',
    path    => '/etc/init.d/jetty',
    target  => "${home}/bin/jetty.sh",
    require => File['jetty home'],
  }

  file { 'jetty log':
    ensure  => directory,
    path    => $log,
    owner   => $user,
    group   => $group,
    recurse => true,
    require => User['jetty user'],
  }

  service { 'jetty':
    ensure     => running,
    name       => 'jetty',
    enable     => true,
    hasrestart => true,
    hasstatus  => false,
    require    => File['jetty init'],
  }

  if ($create_work_dir) {
    file { 'jetty work':
      ensure  => directory,
      path    => "${home}/work",
      owner   => $user,
      group   => $group,
      require => [User['jetty user'], File['jetty home']],
    }
  }

  if ($remove_demo_base) {
    file { 'jetty demo':
      ensure  => absent,
      path    => "${home}/demo-base",
      force   => true,
      require => File['jetty home'],
    }
  }

  file { 'jetty default':
    ensure => present,
    path   => '/etc/default/jetty',
    owner  => 'root',
    group  => 'root',
  }

  $final_jetty_properties.each |$key, $value| {
    file_line { "jetty_properties_${key}":
      path    => '/etc/default/jetty',
      line    => "${key}=${value}",
      match   => "^(${key}=).*$",
      require => File['jetty default'],
      notify  => Service['jetty'],
    }
  }

  if(!empty($java_properties)) {
    validate_hash($java_properties)

    $java_properties.each |$key, $value| {
      file_line { "java_properties_${key}":
        path    => '/etc/default/jetty',
        line    => "${key}=${value}",
        match   => "^(${key}=).*$",
        require => File['jetty default'],
        notify  => Service['jetty'],
      }
    }
  }
}