Puppet Class: gitea

Defined in:
manifests/init.pp

Summary

main class includes all other classes

Overview

Install Gitea, a painless self-hosted Git service. Review module hiera for default parameter values.

Examples:

Basic usage

include gitea

Install current supported release

class { 'gitea':
  ensure => 'installed',
}

Install latest release and keep upgraded

class { 'gitea':
  ensure => 'latest',
}

Install specific supported version

class { 'gitea':
  ensure   => '1.18.0',
}

Install specific version not directly supported

class { 'gitea':
  ensure   => '1.17.0',
  checksum => 'bc4a8e1f5d5f64d4be2e50c387de08d07c062aecdba2f742c2f61c20accfcc46',
}

Parameters:

  • manage_user (Boolean) —

    Should we manage provisioning the user?

  • manage_group (Boolean) —

    Should we manage provisioning the group?

  • manage_home (Boolean) —

    Should we manage provisioning the home directory?

  • owner (String) —

    The user owning gitea

  • group (String) —

    The group owning gitea

  • umask (Pattern[/[0-7]{4}/]) —

    UMask of service process

  • home (Optional[String]) —

    Qualified path to the user home directory

  • proxy (Optional[String]) —

    Download gitea release via specified proxy

  • base_url (String) —

    Download base URL

  • ensure (Variant[Pattern[/\d+\.\d+\.\d+/],Enum['latest','installed']]) —

    Version of gitea to install, ‘installed’, or ‘latest’

  • checksum (Optional[String]) (defaults to: undef) —

    Checksum for the release binary

  • work_path (String) —

    Target directory for the gitea installation

  • default_configuration (Hash) —

    Settings for configuring Gitea. A simple working configuration is provided (see hiera). Generally this parameter should NOT be provided. Instead set the custom_configuration parameter to override built-in defaults.

  • custom_configuration (Hash) —

    Override default configuration for configuring Gitea. The value is merged with the ‘default_configuration` parameter value.

  • manage_service (Boolean) —

    Should we manage a service definition for Gitea?

  • service_epp (String) —

    Path to service epp template file

  • tmpfile_epp (String) —

    Path to tmpfile epp template file

  • robots_txt (String) —

    Allows to provide a www.robotstxt.org/ file to restrict crawling

  • run_path (String) —

    Path to service runtime path

See Also:



93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
 
# File 'manifests/init.pp', line 93

class gitea (
  Boolean $manage_user,
  Boolean $manage_group,
  Boolean $manage_home,
  String $owner,
  String $group,
  Pattern[/[0-7]{4}/] $umask,
  Optional[String] $home,

  Optional[String] $proxy,
  String $base_url,
  Variant[Pattern[/\d+\.\d+\.\d+/],Enum['latest','installed']] $ensure,
  String $work_path,

  Hash $custom_configuration,
  Hash $default_configuration,

  Boolean $manage_service,
  String $service_epp,
  String $tmpfile_epp,
  String $run_path,

  String $robots_txt,

  Optional[String] $checksum = undef,
) {
  # custom validation
  if $ensure in ['latest','installed'] and ($checksum !~ Undef) {
    fail('must not specify a checksum when ensure is latest or installed')
  }

  $base_configuration = {
    '' => {
      'RUN_USER' => $owner,
    },
  }

  $configuration = deep_merge(
    deep_merge($base_configuration, $default_configuration),
  $custom_configuration)

  contain gitea::service::user
  contain gitea::install
  contain gitea::config

  if $manage_service {
    contain gitea::service
    Class['gitea::config']
    ~> Class['gitea::service']
    Class['gitea::install']
    ~> Class['gitea::service']

    Gitea::Custom::File <||>
    ~> Class['gitea::service']
  } else {
    Class['gitea::config']
    -> Gitea::Custom::File <||>
  }

  Class['gitea::service::user']
  -> Class['gitea::install']
  -> Class['gitea::config']
}