Puppet Class: gitea::install

Defined in:
manifests/install.pp

Summary

download and install gitea

Overview

Downloads and installs gitea, and manages the required directory structure

Parameters:

  • packages (Array[String]) —

    List of system packages required by Gitea

  • checksums (Hash) —

    Hash of known version checksums. See data/checksums.yaml



12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
 
# File 'manifests/install.pp', line 12

class gitea::install (
  Array[String] $packages,
  Hash $checksums,
) {
  ensure_packages($packages)

  $bin_path = "${gitea::work_path}/gitea"

  file { [
      $gitea::work_path,
      $gitea::configuration['server']['APP_DATA_PATH'],
      $gitea::configuration['repository']['ROOT'],
      "${gitea::configuration['server']['APP_DATA_PATH']}/sessions",
    ]:
      ensure => 'directory',
      owner  => $gitea::owner,
      group  => $gitea::group,
  }

  $vars = Deferred('gitea::archive_resource', [$bin_path, $gitea::base_url, $checksums, $gitea::ensure, $gitea::checksum])

  archive { 'gitea':
    path          => "${bin_path}.stage",
    source        => Deferred('inline_epp', ['<%= $source %>', $vars]),
    proxy_server  => $gitea::proxy,
    checksum      => Deferred('inline_epp', ['<%= $checksum %>', $vars]),
    checksum_type => Deferred('inline_epp', ['<%= $checksum_type %>', $vars]),
    cleanup       => false,
    extract       => false,
  }
  -> file { "${bin_path}.stage":
    mode => '0755',
  }
  # basic check to ensure the updated release executes
  -> exec { 'gitea-release-check':
    cwd         => $gitea::work_path,
    environment => [
      "HOME=${gitea::work_path}",
      "USER=${gitea::owner}",
      "GITEA_WORK_DIR=${gitea::work_path}",
    ],
    user        => $gitea::owner,
    umask       => $gitea::umask,
    command     => "${bin_path}.stage doctor check --run paths --log-file '' || ${bin_path}.stage doctor --run paths --log-file ''",
    onlyif      => [
      "/usr/bin/env test -f ${gitea::work_path}/custom/conf/app.ini",
      "/usr/bin/env cmp ${bin_path} ${bin_path}.stage; /usr/bin/env test $? -eq 1",
    ],
  }
  -> file { $bin_path:
    source => "${bin_path}.stage",
    mode   => '0755',
  }
}