Defined Type: patch

Defined in:
manifests/init.pp

Summary

Apply patch to a target path

Overview

Examples:

patch { 'patch vendor templates':
  target => '/opt/application/templates',
  source => file("${module_name}/vendor.patch"),
  strip  => 1,
}

Parameters:

  • target (Stdlib::Absolutepath) (defaults to: $title) —

    directory where the patch will be applied

  • content (Optional[String]) (defaults to: undef) —

    text of a unified diff

  • source (Optional[String]) (defaults to: undef) —

    unified diff file

  • strip (Integer) (defaults to: 0) —

    strip the smallest prefix containing num leading slashes from each file name in the patch file

  • loose (Optional[Boolean]) (defaults to: undef) —

    match patterns loosely, in case tabs or spaces have been munged in your files

  • backup (Optional[Boolean]) (defaults to: undef) —

    create backups of successfully patched files



22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
 
# File 'manifests/init.pp', line 22

define patch (
  Stdlib::Absolutepath $target  = $title,
  Optional[String]     $content = undef,
  Optional[String]     $source  = undef,
  Integer              $strip   = 0,
  Optional[Boolean]    $loose   = undef,
  Optional[Boolean]    $backup  = undef,
) {
  require patch::default

  if ($content =~ Undef and $source =~ Undef) {
    fail('content or source required')
  }

  $patch_file = sprintf('%s/%s.patch',
    $patch::cache::directory,
    regsubst(regsubst($title, /\s/, '-', 'G'), /[^\w_-]/, '', 'G'),
  )

  $_loose = ($loose =~ Undef) ? {
    true  => $patch::default::loose,
    false => $loose,
  }
  $_backup = ($backup =~ Undef) ? {
    true  => $patch::default::backup,
    false => $backup,
  }

  $backup_option = $_backup ? {
    true  => '',
    false => '-V never -r -',
  }
  $loose_option = $_loose ? {
    true  => '--ignore-whitespace',
    false => '',
  }

  file { "${title}.patch":
    ensure       => file,
    path         => $patch_file,
    content      => $content,
    source       => $source,
    owner        => $patch::cache::owner,
    group        => $patch::cache::group,
    mode         => $patch::cache::mode,
    validate_cmd => sprintf('cd %s && /usr/bin/env patch --dry-run %s %s --forward --strip %s < %%', $target, $loose_option, $backup_option, $strip),
  }

  -> exec { "${title}.patch":
    command => sprintf('/usr/bin/env patch %s %s --forward --strip %d < %s', $loose_option, $backup_option, $strip, $patch_file),
    unless  => sprintf('/usr/bin/env patch %s --reverse --dry-run --strip %d < %s', $loose_option, $strip, $patch_file),
    cwd     => $target,
  }
}