Puppet Class: cultivator

Defined in:
manifests/init.pp

Summary

Install cultivator service

Overview

Parameters:

  • integration_id (String) —

    sets the GitHub app ID

  • version (String) (defaults to: 'v0.0.14') —

    sets the release tag to use

  • dir (String) (defaults to: '/var/lib/cultivator') —

    sets the root storage directory

  • check_repo (String) (defaults to: 'https://github.com/akerl/repo-checks') —

    sets the path for the check repo

  • bootdelay (String) (defaults to: '300') —

    sets how long to wait before first run

  • frequency (String) (defaults to: '3600') —

    sets how often to run updates



10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
 
# File 'manifests/init.pp', line 10

class cultivator (
  String $integration_id,
  String $version = 'v0.0.14',
  String $dir = '/var/lib/cultivator',
  String $check_repo = 'https://github.com/akerl/repo-checks',
  String $bootdelay = '300',
  String $frequency = '3600'
) {
  $cache_dir = "${dir}/cache"
  $check_dir = "${dir}/checks"
  $private_key_file = "${dir}/key.pem"

  $arch = $facts['os']['architecture'] ? {
    'x86_64'  => 'amd64',
    'arm64'   => 'arm64',
    'aarch64' => 'arm64',
    'arm'     => 'arm',
    default   => 'error',
  }

  $binfile = '/usr/local/bin/cultivator'
  $filename = "cultivator_${downcase($facts['kernel'])}_${arch}"
  $url = "https://github.com/akerl/cultivator/releases/download/${version}/${filename}"

  group { 'cultivator':
    ensure => present,
    system => true,
  }

  user { 'cultivator':
    ensure => present,
    system => true,
    gid    => 'cultivator',
    shell  => '/usr/bin/nologin',
    home   => $dir,
  }

  exec { 'download cultivator':
    command => "/usr/bin/curl -sLo '${binfile}' '${url}' && chmod a+x '${binfile}'",
    unless  => "/usr/bin/test -f ${binfile} && ${binfile} version | grep '${version}'",
  }

  file { [$dir, $check_dir]:
    ensure => directory,
    owner  => 'root',
    group  => 'cultivator',
    mode   => '0750',
  }

  file { $cache_dir:
    ensure => directory,
    owner  => 'cultivator',
    group  => 'cultivator',
    mode   => '0750',
  }

  file { "${dir}/config.yaml":
    ensure  => file,
    mode    => '0640',
    owner   => 'root',
    group   => 'cultivator',
    content => template('cultivator/config.yaml.erb'),
  }

  file { "${dir}/.gitconfig":
    ensure  => file,
    mode    => '0640',
    owner   => 'root',
    group   => 'cultivator',
    content => template('cultivator/gitconfig.erb'),
  }

  vcsrepo { $check_dir:
    ensure   => latest,
    provider => git,
    source   => $check_repo,
  }

  file { '/etc/systemd/system/cultivator.service':
    ensure => file,
    source => 'puppet:///modules/cultivator/cultivator.service',
  }

  file { '/etc/systemd/system/cultivator.timer':
    ensure  => file,
    content => template('cultivator/cultivator.timer.erb'),
  }

  ~> service { 'cultivator.timer':
    ensure  => running,
    enable  => true,
    require => File['/var/lib/cultivator/config.yaml'],
  }
}