Defined Type: disks::lv

Defined in:
manifests/lv.pp

Summary

Create an LV with a filesystem

Overview

Parameters:

  • size (String) —

    sets size of LV

  • vg (String) —

    sets VG to use for LV

  • fstype (Optional[String]) (defaults to: undef) —

    sets filesystem type

  • fsoptions (Optional[String]) (defaults to: undef) —

    sets /etc/fstab mount options for the LV

  • mount (Optional[String]) (defaults to: undef) —

    sets mountpoint for LV (not mounted if undef)

  • lvname (String) (defaults to: $title) —

    sets name for LV



9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
 
# File 'manifests/lv.pp', line 9

define disks::lv (
  String $size,
  String $vg,
  Optional[String] $fstype = undef,
  Optional[String] $fsoptions = undef,
  Optional[String] $mount = undef,
  String $lvname = $title,
) {
  $lv_path = "/dev/${vg}/${lvname}"

  exec { "Create LV ${lv_path}":
    command => "/usr/bin/lvcreate -y -L '${size}' -n '${lvname}' '${vg}'",
    creates => $lv_path,
  }

  if $fstype {
    exec { "Create FS on LV ${lv_path}":
      command => "/usr/bin/mkfs -t '${fstype}' '${lv_path}'",
      onlyif  => "/usr/bin/file -sLb '${lv_path}' | grep '^data$'",
      require => Exec["Create LV ${lv_path}"],
    }
  }

  if $mount {
    mount { $mount:
      ensure  => mounted,
      device  => $lv_path,
      atboot  => true,
      fstype  => $fstype,
      options => $fsoptions,
      dump    => '0',
      pass    => '2',
    }
  }
}