Puppet Class: frameproxy

Defined in:
manifests/init.pp

Summary

Configure mitmproxy instance for frame

Overview

Parameters:

  • datadir (String) —

    sets location to store cached photos and TLS cert

  • proxy_hostname (String) —

    sets hostname of proxy endpoint for certificate generation

  • proxy_aws_access_key_id (String) —

    sets the aws key to use for route53 challenge

  • proxy_aws_secret_access_key (String) —

    sets the aws secret key to use for the route53 challenge

  • intercept_hostname (String) —

    sets hostname of frame api endpoint for certificate generation

  • intercept_aws_access_key_id (String) —

    sets the aws key to use for route53 challenge

  • intercept_aws_secret_access_key (String) —

    sets the aws secret key to use for the route53 challenge

  • email (String) —

    sets the contact address for the certificate

  • ip (String) (defaults to: '172.17.0.4') —

    sets the IP to use for mitmproxy docker container



12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
 
# File 'manifests/init.pp', line 12

class frameproxy (
  String $datadir,
  String $proxy_hostname,
  String $proxy_aws_access_key_id,
  String $proxy_aws_secret_access_key,
  String $intercept_hostname,
  String $intercept_aws_access_key_id,
  String $intercept_aws_secret_access_key,
  String $email,
  String $ip = '172.17.0.4',
) {
  $proxy_hook_script =  "#!/usr/bin/env bash
cat \$LEGO_CERT_KEY_PATH \$LEGO_CERT_PATH > ${datadir}/tls/proxy_cert
/usr/bin/systemctl restart container@frameproxy"

  $intercept_hook_script =  "#!/usr/bin/env bash
cat \$LEGO_CERT_KEY_PATH \$LEGO_CERT_PATH > ${datadir}/tls/intercept_cert
/usr/bin/systemctl restart container@frameproxy"

  $command = [
    'mitmdump',
    "--allow-hosts ${intercept_hostname}",
    "--certs ${intercept_hostname}=/opt/tls/intercept_cert",
    "--certs ${proxy_hostname}=/opt/tls/proxy_cert",
    '-s /opt/scripts/cache.py',
  ]

  firewall { '100 dnat for mitmproxy':
    chain  => 'DOCKER_EXPOSE',
    jump   => 'DNAT',
    proto  => 'tcp',
    dport  => 8080,
    todest => "${ip}:8080",
    table  => 'nat',
  }

  file { [
      $datadir,
      "${datadir}/cache",
      "${datadir}/tls",
      "${datadir}/scripts",
    ]:
      ensure => directory,
  }

  file { "${datadir}/scripts/cache.py":
    ensure => file,
    source => 'puppet:///modules/frameproxy/cache.py',
  }

  acme::certificate { $proxy_hostname:
    hook_script           => $proxy_hook_script,
    aws_access_key_id     => $proxy_aws_access_key_id,
    aws_secret_access_key => $proxy_aws_secret_access_key,
    email                 => $email,
  }

  acme::certificate { $intercept_hostname:
    hook_script           => $intercept_hook_script,
    aws_access_key_id     => $intercept_aws_access_key_id,
    aws_secret_access_key => $intercept_aws_secret_access_key,
    email                 => $email,
  }

  docker::container { 'frameproxy':
    image     => 'mitmproxy/mitmproxy',
    args      => [
      "--ip ${ip}",
      "-v ${datadir}/cache:/opt/cache",
      "-v ${datadir}/tls:/opt/tls",
      "-v ${datadir}/scripts:/opt/scripts",
    ],
    cmd       => join($command, ' '),
    subscribe => [
      File["${datadir}/scripts/cache.py"],
      Acme::Certificate[$proxy_hostname],
      Acme::Certificate[$intercept_hostname],
    ],
  }
}