Puppet Class: goat

Defined in:
manifests/init.pp

Summary

Install Goatcounter server

Overview

Parameters:

  • hostname (String) —

    is the hostname for the goat server

  • admin_email (String) —

    is the email address to access metrics

  • admin_password (String) —

    is the password to access metrics

  • aws_access_key_id (String) —

    sets the AWS key to use for Route53 challenge

  • aws_secret_access_key (String) —

    sets the AWS secret key to use for the Route53 challenge

  • version (String) (defaults to: 'v2.2.3') —

    sets the goatcounter version to use

  • backup_target (Optional[String]) (defaults to: undef) —

    sets the target repo for backups

  • backup_watchdog (Optional[String]) (defaults to: undef) —

    sets the watchdog URL to confirm backups are working

  • backup_password (Optional[String]) (defaults to: undef) —

    sets the encryption key for backup snapshots

  • backup_environment (Optional[Hash[String, String]]) (defaults to: undef) —

    sets the env vars to use for backups



13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
 
# File 'manifests/init.pp', line 13

class goat (
  String $hostname,
  String $admin_email,
  String $admin_password,
  String $aws_access_key_id,
  String $aws_secret_access_key,
  String $version = 'v2.2.3',
  Optional[String] $backup_target = undef,
  Optional[String] $backup_watchdog = undef,
  Optional[String] $backup_password = undef,
  Optional[Hash[String, String]] $backup_environment = undef,
) {
  $arch = $facts['os']['architecture'] ? {
    'x86_64'  => 'amd64',
    'arm64'   => 'arm64',
    'aarch64' => 'arm64',
    'arm'     => 'arm',
    default   => 'error',
  }

  $binfile = '/usr/local/bin/goatcounter'
  $filename = "goatcounter-dev-linux-${arch}.gz"
  $url = "https://github.com/arp242/goatcounter/releases/download/${version}/${filename}"

  $dbdir = '/var/lib/goatcounter'
  $dbfile = "${dbdir}/goatcounter.sqlite3"
  $dburl = "sqlite+${dbfile}"
  $dbcmd = "${binfile} db create site -createdb \
  -vhost ${hostname} -user.email ${admin_email} -user.password ${admin_password} -db ${dburl}"

  group { 'goatcounter':
    ensure => present,
    system => true,
  }

  user { 'goatcounter':
    ensure => present,
    system => true,
    gid    => 'goatcounter',
    shell  => '/usr/bin/nologin',
    home   => '/var/lib/goatcounter',
  }

  exec { 'download goatcounter':
    command => "/usr/bin/curl -sL '${url}' | gunzip > ${binfile} && chmod a+x ${binfile}",
    unless  => '/usr/local/bin/goatcounter version | grep version=dev',
  }

  -> file { [$dbdir, '/var/log/goatcounter']:
    ensure => directory,
    owner  => 'goatcounter',
    group  => 'goatcounter',
  }

  -> exec { $dbcmd:
    user    => 'goatcounter',
    creates => $dbfile,
  }

  -> file { '/etc/systemd/system/goatcounter.service':
    ensure => file,
    source => 'puppet:///modules/goat/goatcounter.service',
  }

  ~> service { 'goatcounter':
    ensure => running,
    enable => true,
  }

  nginx::site { $hostname:
    proxy_target          => 'http://localhost:8081',
    aws_access_key_id     => $aws_access_key_id,
    aws_secret_access_key => $aws_secret_access_key,
    email                 => $admin_email,
  }

  if $backup_target != '' {
    backup::repo { 'goat':
      source       => $dbdir,
      target       => $backup_target,
      watchdog_url => $backup_watchdog,
      password     => $backup_password,
      environment  => $backup_environment,
    }
  }
}