Puppet Class: homeassistant

Defined in:
manifests/init.pp

Summary

Configure HomeAssistant instance

Overview

Parameters:

  • hostname (String) —

    sets the hostname for grafana

  • datadir (String) —

    sets where the data is persisted

  • aws_access_key_id (String) —

    sets the AWS key to use for Route53 challenge

  • aws_secret_access_key (String) —

    sets the AWS secret key to use for the Route53 challenge

  • email (String) —

    sets the contact address for the certificate

  • backup_target (Optional[String]) (defaults to: undef) —

    sets the target repo for backups

  • backup_watchdog (Optional[String]) (defaults to: undef) —

    sets the watchdog URL to confirm backups are working

  • backup_password (Optional[String]) (defaults to: undef) —

    sets the encryption key for backup snapshots

  • backup_environment (Optional[Hash[String, String]]) (defaults to: undef) —

    sets the env vars to use for backups

  • backup_rclone (Optional[String]) (defaults to: undef) —

    sets the config for an rclone backend



13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
 
# File 'manifests/init.pp', line 13

class homeassistant (
  String $hostname,
  String $datadir,
  String $aws_access_key_id,
  String $aws_secret_access_key,
  String $email,
  Optional[String] $backup_target = undef,
  Optional[String] $backup_watchdog = undef,
  Optional[String] $backup_password = undef,
  Optional[Hash[String, String]] $backup_environment = undef,
  Optional[String] $backup_rclone = undef,
) {
  $hook_script =  "#!/usr/bin/env bash
cp \$LEGO_CERT_PATH ${datadir}/certs/cert
cp \$LEGO_CERT_KEY_PATH ${datadir}/certs/key
/usr/bin/systemctl restart container@homeassistant"

  file { [$datadir, "${datadir}/config", "${datadir}/certs"]:
    ensure => directory,
  }

  -> acme::certificate { $hostname:
    hook_script           => $hook_script,
    aws_access_key_id     => $aws_access_key_id,
    aws_secret_access_key => $aws_secret_access_key,
    email                 => $email,
  }

  -> firewall { '100 allow inbound 443 to homeassistant':
    dport  => 443,
    proto  => 'tcp',
    action => 'accept',
  }

  -> docker::container { 'homeassistant':
    image   => 'ghcr.io/home-assistant/home-assistant:stable',
    network => 'host',
    args    => [
      '--privileged',
      '-e TZ=Etc/UTC',
      "-v ${datadir}/config:/config",
      "-v ${datadir}/certs:/ssl",
      '--device /dev/ttyUSB0:/dev/ttyUSB0',
      '--device /dev/ttyUSB1:/dev/ttyUSB1',
    ],
    cmd     => '',
  }

  if $backup_rclone != undef {
    backup::repo { 'homeassistant':
      source        => "${datadir}/config",
      target        => $backup_target,
      watchdog_url  => $backup_watchdog,
      password      => $backup_password,
      environment   => $backup_environment,
      rclone_config => $backup_rclone,
    }
  }
}