Defined Type: kvm::guest

Defined in:
manifests/guest.pp

Summary

Defines a guest VM

Overview

Parameters:

  • image (String) —

    sets the system image to use to bootstrap the guest

  • disks (Hash[String, Hash]) —

    sets the LVs to create for the guest

  • ram (Integer) (defaults to: 1024) —

    sets the memory given to the VM

  • cores (Integer) (defaults to: 1) —

    sets the CPU core count given to the VM

  • vm_name (String) (defaults to: $title) —

    sets the name of the VM

  • bridge (Optional[String]) (defaults to: undef) —

    sets the bridge interface to use for networking



9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
 
# File 'manifests/guest.pp', line 9

define kvm::guest (
  String $image,
  Hash[String, Hash] $disks,
  Integer $ram = 1024,
  Integer $cores = 1,
  String $vm_name = $title,
  Optional[String] $bridge = undef,
) {
  $disks.each | String $name, Hash $options | {
    disks::lv { "guest-${vm_name}-${name}":
      * => $options,
    }
  }

  $image_path = "${kvm::image_path}/${image}"
  $root_device = "/dev/${disks['root']['vg']}/guest-${vm_name}-root"
  $vnc_path = "${kvm::console_path}/vnc/${vm_name}.sock"
  $serial_path = "${kvm::console_path}/serial/${vm_name}.sock"
  $monitor_path = "${kvm::console_path}/monitor/${vm_name}.sock"
  $mac_address_seed = fqdn_rand(4294967295, "macaddress-${vm_name}", true)

  exec { "Create root for ${root_device}":
    command => "/usr/bin/qemu-img convert -O raw -n '${image_path}' '${root_device}'",
    onlyif  => "/usr/bin/file -sLb '${root_device}' | grep '^data$'",
    require => Disks::Lv["guest-${vm_name}-root"],
  }

  -> file { "/etc/kvm/${vm_name}":
    ensure  => file,
    content => template('kvm/guest.conf.erb'),
    require => File['/etc/qemu/bridge.conf'],
  }

  ~> service { "kvm@${vm_name}":
    ensure => running,
    enable => true,
  }
}