Puppet Class: slackmastodon

Defined in:
manifests/init.pp

Summary

Install slack-mastodon service

Overview

Parameters:

  • mastodon_server (String) —

    sets the Mastodon server to connect to

  • mastodon_access_token (String) —

    sets the token to use for Mastodon API auth

  • slack_channel (String) —

    sets the Slack channel to publish to

  • slack_bot_token (String) —

    sets the bot token for the Slack API

  • version (String) (defaults to: 'v0.0.4') —

    sets the slack-mastodon tag to use

  • bootdelay (String) (defaults to: '300') —

    sets how long to wait before first run

  • frequency (String) (defaults to: '300') —

    sets how often to run updates



10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
 
# File 'manifests/init.pp', line 10

class slackmastodon (
  String $mastodon_server,
  String $mastodon_access_token,
  String $slack_channel,
  String $slack_bot_token,
  String $version = 'v0.0.4',
  String $bootdelay = '300',
  String $frequency = '300'
) {
  $arch = $facts['os']['architecture'] ? {
    'x86_64'  => 'amd64',
    'arm64'   => 'arm64',
    'aarch64' => 'arm64',
    'arm'     => 'arm',
    default   => 'error',
  }

  $binfile = '/usr/local/bin/slack-mastodon'
  $filename = "slack-mastodon_${downcase($facts['kernel'])}_${arch}"
  $url = "https://github.com/akerl/slack-mastodon/releases/download/${version}/${filename}"

  group { 'slackmastodon':
    ensure => present,
    system => true,
  }

  user { 'slackmastodon':
    ensure => present,
    system => true,
    gid    => 'slackmastodon',
    shell  => '/usr/bin/nologin',
    home   => '/var/lib/slackmastodon',
  }

  exec { 'download slackmastodon':
    command => "/usr/bin/curl -sLo '${binfile}' '${url}' && chmod a+x '${binfile}'",
    unless  => "/usr/bin/test -f ${binfile} && ${binfile} version | grep '${version}'",
  }

  file { [
      '/var/lib/slackmastodon',
      '/var/lib/slackmastodon/.config',
      '/var/lib/slackmastodon/.config/slack-mastodon',
    ]:
      ensure => directory,
      owner  => 'slackmastodon',
      group  => 'slackmastodon',
      mode   => '0750',
  }

  file { '/var/lib/slackmastodon/.config/slack-mastodon/config.yml':
    ensure  => file,
    mode    => '0640',
    owner   => 'slackmastodon',
    group   => 'slackmastodon',
    content => template('slackmastodon/config.yml.erb'),
  }

  file { '/etc/systemd/system/slack-mastodon.service':
    ensure => file,
    source => 'puppet:///modules/slackmastodon/slack-mastodon.service',
  }

  file { '/etc/systemd/system/slack-mastodon.timer':
    ensure  => file,
    content => template('slackmastodon/slack-mastodon.timer.erb'),
  }

  ~> service { 'slack-mastodon.timer':
    ensure  => running,
    enable  => true,
    require => File['/var/lib/slackmastodon/.config/slack-mastodon/config.yml'],
  }
}