Puppet Class: teslamate

Defined in:
manifests/init.pp

Summary

Configure TeslaMate instance

Overview

Parameters:

  • datadir (String) —

    handles storage of Postgres and MQTT data

  • database_password (String) —

    sets the postgres password for teslamate

  • encryption_key (String) —

    sets the key used to encrypt tesla API tokens

  • teslamate_ip (String) (defaults to: '172.17.0.2') —

    sets the IP of the teslamate container

  • postgres_ip (String) (defaults to: '172.17.0.3') —

    sets the IP of the postgres container

  • mqtt_ip (String) (defaults to: '172.17.0.4') —

    sets the IP of the mqtt container

  • postgres_watchdog (Optional[String]) (defaults to: undef) —

    sets the watchdog URL for postgres dumps

  • backup_target (Optional[String]) (defaults to: undef) —

    sets the target repo for backups

  • backup_watchdog (Optional[String]) (defaults to: undef) —

    sets the watchdog URL to confirm backups are working

  • backup_password (Optional[String]) (defaults to: undef) —

    sets the encryption key for backup snapshots

  • backup_environment (Optional[Hash[String, String]]) (defaults to: undef) —

    sets the env vars to use for backups

  • backup_rclone (Optional[String]) (defaults to: undef) —

    sets the config for an rclone backend



15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
 
# File 'manifests/init.pp', line 15

class teslamate (
  String $datadir,
  String $database_password,
  String $encryption_key,
  String $teslamate_ip = '172.17.0.2',
  String $postgres_ip = '172.17.0.3',
  String $mqtt_ip = '172.17.0.4',
  Optional[String] $postgres_watchdog = undef,
  Optional[String] $backup_target = undef,
  Optional[String] $backup_watchdog = undef,
  Optional[String] $backup_password = undef,
  Optional[Hash[String, String]] $backup_environment = undef,
  Optional[String] $backup_rclone = undef,
) {
  firewall { '100 dnat for teslamate':
    chain  => 'DOCKER_EXPOSE',
    jump   => 'DNAT',
    proto  => 'tcp',
    dport  => 80,
    todest => "${teslamate_ip}:4000",
    table  => 'nat',
  }

  firewall { '100 dnat for postgres':
    chain  => 'DOCKER_EXPOSE',
    jump   => 'DNAT',
    proto  => 'tcp',
    dport  => 5432,
    todest => "${postgres_ip}:5432",
    table  => 'nat',
  }

  firewall { '100 dnat for mqtt':
    chain  => 'DOCKER_EXPOSE',
    jump   => 'DNAT',
    proto  => 'tcp',
    dport  => 1883,
    todest => "${mqtt_ip}:1883",
    table  => 'nat',
  }

  firewall { '101 allow cross container from teslamate to postgres':
    chain       => 'FORWARD',
    action      => 'accept',
    proto       => 'tcp',
    source      => $teslamate_ip,
    destination => $postgres_ip,
    dport       => 5432,
  }

  firewall { '101 allow cross container from teslamate to mqtt':
    chain       => 'FORWARD',
    action      => 'accept',
    proto       => 'tcp',
    source      => $teslamate_ip,
    destination => $mqtt_ip,
    dport       => 1883,
  }

  file { [
      $datadir,
      "${datadir}/backup",
      "${datadir}/postgres",
      "${datadir}/mqtt_config",
      "${datadir}/mqtt_data",
    ]:
      ensure => directory,
  }

  docker::container { 'postgres':
    image   => 'postgres:14',
    args    => [
      "--ip ${postgres_ip}",
      "-v ${datadir}/postgres:/var/lib/postgresql/data",
      '-e POSTGRES_USER=teslamate',
      "-e POSTGRES_PASSWORD=${database_password}",
      '-e POSTGRES_DB=teslamate',
    ],
    cmd     => '-c ssl=on -c ssl_cert_file=/etc/ssl/certs/ssl-cert-snakeoil.pem -c ssl_key_file=/etc/ssl/private/ssl-cert-snakeoil.key',
    require => File["${datadir}/postgres"],
  }

  docker::container { 'mqtt':
    image   => 'eclipse-mosquitto:2',
    args    => [
      "--ip ${mqtt_ip}",
      "-v ${datadir}/mqtt_data:/mosquitto/data",
      "-v ${datadir}/mqtt_config:/mosquitto/config",
    ],
    cmd     => 'mosquitto -c /mosquitto-no-auth.conf',
    require => [File["${datadir}/mqtt_config"], File["${datadir}/mqtt_data"]],
  }

  docker::container { 'teslamate':
    image => 'teslamate/teslamate:latest',
    args  => [
      "--ip ${teslamate_ip}",
      "-e ENCRYPTION_KEY=${encryption_key}",
      '-e DATABASE_USER=teslamate',
      "-e DATABASE_PASS=${database_password}",
      '-e DATABASE_NAME=teslamate',
      "-e DATABASE_HOST=${postgres_ip}",
      "-e MQTT_HOST=${mqtt_ip}",
    ],
    cmd   => '',
  }

  file { '/usr/local/bin/teslamate-backup.sh':
    ensure => file,
    source => 'puppet:///modules/teslamate/teslamate-backup.sh',
    mode   => '0755',
  }

  file { '/etc/systemd/system/teslamate-backup.service':
    ensure  => file,
    content => template('teslamate/teslamate-backup.service.erb'),
    notify  => Service['teslamate-backup.timer'],
  }

  file { '/etc/systemd/system/teslamate-backup.timer':
    ensure => file,
    source => 'puppet:///modules/teslamate/teslamate-backup.timer',
    notify => Service['teslamate-backup.timer'],
  }

  service { 'teslamate-backup.timer':
    ensure => running,
    enable => true,
  }

  tidy { "${datadir}/backup weekly":
    path    => "${datadir}/backup",
    age     => '1d',
    recurse => true,
    matches => 'dump_??????{01,07,14,21,28}-??????.sql',
  }

  tidy { "${datadir}/backup all":
    path    => "${datadir}/backup",
    age     => '14d',
    recurse => true,
    matches => 'dump_*.sql',
  }

  if $backup_target != '' {
    backup::repo { 'teslamate':
      source        => "${datadir}/backup",
      target        => $backup_target,
      watchdog_url  => $backup_watchdog,
      password      => $backup_password,
      environment   => $backup_environment,
      rclone_config => $backup_rclone,
    }
  }
}