Puppet Class: zwave

Defined in:
manifests/init.pp

Summary

Configure ZWavejs2Mqtt

Overview

Parameters:

  • datadir (String) —

    sets where the data is persisted

  • dongle (String) —

    sets the device path for the USB dongle

  • hostname (String) —

    is the hostname for log submission

  • aws_access_key_id (String) —

    sets the AWS key to use for Route53 challenge

  • aws_secret_access_key (String) —

    sets the AWS secret key to use for the Route53 challenge

  • email (String) —

    sets the contact address for the certificate

  • container_ip (String) (defaults to: '172.17.0.2') —

    sets the IP address for the docker container

  • port (Integer) (defaults to: 8443) —

    sets the port to listen on

  • backup_target (Optional[String]) (defaults to: undef) —

    sets the target repo for backups

  • backup_watchdog (Optional[String]) (defaults to: undef) —

    sets the watchdog URL to confirm backups are working

  • backup_password (Optional[String]) (defaults to: undef) —

    sets the encryption key for backup snapshots

  • backup_environment (Optional[Hash[String, String]]) (defaults to: undef) —

    sets the env vars to use for backups

  • backup_rclone (Optional[String]) (defaults to: undef) —

    sets the config for an rclone backend



16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
 
# File 'manifests/init.pp', line 16

class zwave (
  String $datadir,
  String $dongle,
  String $hostname,
  String $aws_access_key_id,
  String $aws_secret_access_key,
  String $email,
  String $container_ip = '172.17.0.2',
  Integer $port = 8443,
  Optional[String] $backup_target = undef,
  Optional[String] $backup_watchdog = undef,
  Optional[String] $backup_password = undef,
  Optional[Hash[String, String]] $backup_environment = undef,
  Optional[String] $backup_rclone = undef,
) {
  file { [$datadir, "${datadir}/store"]:
    ensure => directory,
  }

  -> docker::container { 'zwave':
    image => 'zwavejs/zwavejs2mqtt:latest',
    args  => [
      "--device=${dongle}:/dev/zwave",
      "-v ${datadir}/store:/usr/src/app/store",
    ],
    cmd   => '',
  }

  nginx::site { $hostname:
    proxy_target          => "http://${container_ip}:8091",
    aws_access_key_id     => $aws_access_key_id,
    aws_secret_access_key => $aws_secret_access_key,
    email                 => $email,
    csp                   => "default-src 'self' http: https: ws: wss: data: blob: 'unsafe-inline' 'unsafe-eval'; frame-ancestors 'self';",
    port                  => $port,
  }

  if $backup_target != '' {
    backup::repo { 'zwave':
      source        => $datadir,
      target        => $backup_target,
      watchdog_url  => $backup_watchdog,
      password      => $backup_password,
      environment   => $backup_environment,
      rclone_config => $backup_rclone,
    }
  }
}