Puppet Class: fluentbit

Defined in:

manifests/init.pp

Summary

Installs and configures fluentbit

Overview

Examples:

include fluentbit

Parameters:

• manage_package_repo (Boolean) —

  Installs the package repositories

• service_name (String[1]) —

  the td-agent-bit service name

• input_plugins (Array[Fluentbit::Plugin]) —

  Hash of the INPUT plugins to be configured

• output_plugins (Array[Fluentbit::Plugin]) —

  Hash of the OUTPUT plugins to be configured

• filter_plugins (Array[Fluentbit::Plugin]) —

  Hash of the filter to be configured

• manage_package_repo —

  Installs the package repositories

• repo_key_fingerprint (String[1]) —

  GPG key identifier of the repository

• repo_key_location (Stdlib::HTTPUrl) —

  GPG key location

• package_ensure (String[1]) —

  Whether to install the Fluentbit package, and what version to install. Values: ‘present’, ‘latest’, or a specific version number. Default value: ‘present’.

• package_name (String[1]) —

  Specifies the Fluentbit package to manage. Default value: ‘td-agent-bit’

• manage_service (Boolean) —

  Whether to manage the service at all. Default value: true

• service_enable (Boolean) —

  Whether to enable the fluentbit service at boot. Default value: true.

• service_ensure (Stdlib::Ensure::Service) —

  Whether the fluentbit service should be running. Default value: ‘running’.

• service_manage —

  Whether to manage the fluentbit service. Default value: true.

• service_hasstatus —

  Whether the service has a functional status command. Default value: true.

• service_hasrestart —

  Whether the service has a restart command. Default value: true.

• manage_config_dir (Boolean) —

  Whether to manage the configuration directory. When enabled, will remove all unmanaged files from the directory the configuration resides in. Default value: true

• config_file (Stdlib::Absolutepath) —

  Path of the daemon configuration.

• config_file_mode (Stdlib::Filemode) —

  File mode to apply to the daemon configuration file

• storage_path (Optional[Stdlib::Absolutepath]) —

  Set an optional location in the file system to store streams and chunks of data. If this parameter is not set, Input plugins can only use in-memory buffering.

• storage_sync (Optional[Enum['normal', 'full']]) —

  Configure the synchronization mode used to store the data into the file system. It can take the values normal or full. Default value: ‘normal’

• storage_checksum (Boolean) —

  Enable the data integrity check when writing and reading data from the filesystem. The storage layer uses the CRC32 algorithm. Default value: false

• storage_backlog_mem_limit (Optional[String[1]]) —

  If storage.path is set, Fluent Bit will look for data chunks that were not delivered and are still in the storage layer, these are called backlog data. This option configure a hint of maximum value of memory to use when processing these records. Default value: 5M

• manage_plugins_file (Boolean) —

  Whether to manage the enabled external plugins

• plugins_file (Stdlib::Absolutepath) —

  A plugins configuration file allows to define paths for external plugins.

• plugins (Array[Stdlib::Absolutepath]) —

  List of external plugin objects to enable

• manage_streams_file (Boolean) —

  Whether to manage the stream processing configuration

• streams_file (Stdlib::Absolutepath) —

  Path for the Stream Processor configuration file.

• streams (Array[Fluentbit::Stream]) —

  Stream processing tasks

• manage_parsers_file (Boolean) —

  Whether to manage the parser definitions

• parsers_file (Stdlib::Absolutepath) —

  Path for a parsers configuration file. Multiple Parsers_File entries can be used.

• parsers (Array[Fluentbit::Parser]) —

  List of parser definitions. The default value consists of all the available definitions provided by the upstream project as of version 1.3

• flush (Integer) —

  Set the flush time in seconds. Everytime it timeouts, the engine will flush the records to the output plugin.

• daemon (Boolean) —

  Boolean value to set if Fluent Bit should run as a Daemon (background) or not. Allowed values are: yes, no, on and off.

• log_file (Optional[Stdlib::Absolutepath]) —

  Absolute path for an optional log file.

• log_level (Enum['error', 'warning', 'info', 'debug', 'trace']) —

  Set the logging verbosity level. Values are: error, info, debug and trace. Values are accumulative, e.g: if ‘debug’ is set, it will include error, info and debug. Note that trace mode is only available if Fluent Bit was built with the WITH_TRACE option enabled.

• http_server (Boolean) —

  Enable built-in HTTP Server

• http_listen (Stdlib::IP::Address::Nosubnet) —

  Set listening interface for HTTP Server when it’s enabled

• http_port (Stdlib::Port) —

  Set TCP Port for the HTTP Server

• coro_stack_size (Integer) —

  Set the coroutines stack size in bytes. The value must be greater than the page size of the running system.

• variables (Hash) —

  macro definitions to use in the configuration file the will be registered using the *@SET* command.

• service_has_status (Boolean)
• service_has_restart (Boolean)

See Also:

• https://docs.fluentbit.io/manual/

# File 'manifests/init.pp', line 141

class fluentbit (
  Boolean $manage_package_repo,
  Stdlib::HTTPUrl $repo_key_location,
  String[1] $repo_key_fingerprint,
  String[1] $package_ensure,
  String[1] $package_name,
  Boolean $manage_service,
  Boolean $service_enable,
  Boolean $service_has_status,
  Boolean $service_has_restart,
  Stdlib::Ensure::Service $service_ensure,
  String[1] $service_name,
  Boolean $manage_config_dir,

  Array[Fluentbit::Plugin] $input_plugins,
  Array[Fluentbit::Plugin] $output_plugins,
  Array[Fluentbit::Plugin] $filter_plugins,

  Array[Fluentbit::Parser] $parsers,
  Array[Fluentbit::Stream] $streams,
  Array[Stdlib::Absolutepath] $plugins,

  Stdlib::Absolutepath $config_file,
  Stdlib::Filemode $config_file_mode,
  Integer $flush,
  Boolean $daemon,
  Optional[Stdlib::Absolutepath] $log_file,
  Enum['error', 'warning', 'info', 'debug', 'trace'] $log_level,
  Boolean $manage_parsers_file,
  Stdlib::Absolutepath $parsers_file,
  Boolean $manage_plugins_file,
  Stdlib::Absolutepath $plugins_file,
  Boolean $manage_streams_file,
  Stdlib::Absolutepath $streams_file,
  Boolean $http_server,
  Stdlib::IP::Address::Nosubnet $http_listen,
  Stdlib::Port $http_port,

  Optional[Stdlib::Absolutepath] $storage_path,
  Optional[Enum['normal', 'full']] $storage_sync,
  Boolean $storage_checksum,
  Optional[String[1]] $storage_backlog_mem_limit,

  Hash $variables,
  Integer $coro_stack_size,
) {

  contain fluentbit::repo
  contain fluentbit::install
  contain fluentbit::config
  contain fluentbit::service

  Class['::fluentbit::repo']
    -> Class['::fluentbit::install']
    -> Class['::fluentbit::config']
    ~> Class['::fluentbit::service']

  $input_plugins.each |$index, $plugin| {
    $name = $plugin['name']

    Resource["fluentbit::input::${name}"] {
      "i${index}": * => merge($plugin['properties']);
    }
  }

  $output_plugins.each |$index, $plugin| {
    $name = $plugin['name']

    Resource["fluentbit::output::${name}"] {
      "o${index}": * => merge($plugin['properties']);
    }
  }

  $filter_plugins.each |$index, $plugin| {
    $name = $plugin['name']

    Resource["fluentbit::filter::${name}"] {
      "f${index}": * => merge($plugin['properties']);
    }
  }
}