Puppet Class: nexus::service

Defined in:
manifests/service.pp

Overview

Class: nexus::service

Maintains the Nexus service

Parameters

NONE

Variables

nexus_home

The home location for the service

nexus_user

The user to run the service as

version

The version of nexus

Examples

class{ ‘nexus::service’:

nexus_home => '/srv/nexus',
nexus_user => 'nexus',
version    => '2.8.0',

}

Authors

Tom McLaughlin <tmclaughlin@hubspot.com>

Copyright 2013 Hubspot

Parameters:

  • nexus_home (Any) (defaults to: $::nexus::nexus_home)
  • nexus_user (Any) (defaults to: $::nexus::nexus_user)
  • nexus_group (Any) (defaults to: $::nexus::nexus_group)
  • version (Any) (defaults to: $::nexus::version) 


36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
 
# File 'manifests/service.pp', line 36

class nexus::service (
  $nexus_home = $::nexus::nexus_home,
  $nexus_user = $::nexus::nexus_user,
  $nexus_group = $::nexus::nexus_group,
  $version = $::nexus::version,
) {
  $nexus_script = "${nexus_home}/bin/nexus"

  if ($::operatingsystem == 'Debian' and versioncmp($::operatingsystemrelease, '8.0') > 0) or
     ($::operatingsystem == 'Ubuntu' and versioncmp($::operatingsystemrelease, '15.04') > 0) {
    file { '/lib/systemd/system/nexus.service':
      mode    => '0644',
      owner   => 'root',
      group   => 'root',
      content => template('nexus/nexus.systemd.erb'),
    } ->
    service { 'nexus':
      ensure => running,
      name   => 'nexus',
      enable => true,
    }

  } else {

    file_line{ 'nexus_NEXUS_HOME':
      path  => $nexus_script,
      match => '^#?NEXUS_HOME=',
      line  => "NEXUS_HOME=${nexus_home}",
    }

    file{ '/etc/init.d/nexus':
      ensure  => 'link',
      target  => $nexus_script,
      require => [
        File_line['nexus_NEXUS_HOME'],
        File_line['nexus_RUN_AS_USER']
      ],
      notify  => Service['nexus']
    }

    if $version !~ /\d.*/ or versioncmp($version, '2.8.0') >= 0 {
      $status_line = "env run_as_user=${nexus_user} /etc/init.d/nexus status"

      file_line{ 'nexus_RUN_AS_USER':
        path  => $nexus_script,
        match => '^run_as_user\=',
        line  => "run_as_user=\${run_as_user:-${nexus_user}}",
      }

    } else {
      $status_line = 'env run_as_user=root /etc/init.d/nexus status'

      file_line{ 'nexus_RUN_AS_USER':
        path  => $nexus_script,
        match => '^#?RUN_AS_USER=',
        line  => "RUN_AS_USER=\${run_as_user:-${nexus_user}}",
      }
    }

    service{ 'nexus':
      ensure  => running,
      enable  => true,
      status  => $status_line,
      require => [File['/etc/init.d/nexus'],
        File_line['nexus_NEXUS_HOME'],
        File_line['nexus_RUN_AS_USER'],]
    }
  }
}