Puppet Class: ilmt

Inherits:
ilmt::params
Defined in:
manifests/init.pp

Overview

Class: ilmt

This class deploys the IBM License Metric Tool.

As a prerequisite for using this class, you must download the binary RPM package from IBM’s support site and placing this package somewhere within your puppetmaster’s fileserver.

Parameters

ensure

Set this parameter to "present" to install the package and start the agent,
"absent" to stop the agent and uninstall the package, "disabled" to install
the package and stop the agent, and a version string to install a specific
version of the package and start the agent.

package

This package may contain a Puppet fileserver URL pointing to the location
of the binary RPM package.  If no value is provided for this parameter,
Puppet will attempt to install the binary RPM package via yum.

securitylevel

Set this parameter to 0 for no encryption, 1 for server certificate
encryption (you must provide a value for the *servercert* parameter), or 2
for agent certificate encryption (you must provide values for the
*servercert* and *agentcert* parameters).

servercert

Provide the string content of the server public certificate.

agentcert

Provide the string content of the agent public certificate.

Examples

class { ilmt:
  package => 'puppet:///depot/ILMT-TAD4D-agent-7.5.0.115-linux-x86.rpm',
}

Authors

Steve Huff <steve_huff@harvard.edu>

Copyright 2013 President and Fellows of Harvard University

Parameters:

  • ensure (Any) (defaults to: $ilmt::params::ensure)
  • agentcert (Any) (defaults to: $ilmt::params::agentcertfilepath)
  • agentcertfilepath (Any) (defaults to: $ilmt::params::agentcertfilepath)
  • agenttemppath (Any) (defaults to: $ilmt::params::agenttemppath)
  • citinstallpath (Any) (defaults to: $ilmt::params::citinstallpath)
  • fipsenabled (Any) (defaults to: $ilmt::params::fipsenabled)
  • installservercertificate (Any) (defaults to: $ilmt::params::installservercertificate)
  • messagehandleraddress (Any) (defaults to: $ilmt::params::messagehandleraddress)
  • package (Any) (defaults to: $ilmt::params::package)
  • port (Any) (defaults to: $ilmt::params::port)
  • proxyaddress (Any) (defaults to: $ilmt::params::proxyaddress)
  • proxyport (Any) (defaults to: $ilmt::params::proxyport)
  • scangroup (Any) (defaults to: $ilmt::params::scangroup)
  • secureall (Any) (defaults to: $ilmt::params::secureall)
  • secureauth (Any) (defaults to: $ilmt::params::secureauth)
  • securitylevel (Any) (defaults to: $ilmt::params::securitylevel)
  • servercert (Any) (defaults to: $ilmt::params::servercert)
  • servercertfilepath (Any) (defaults to: $ilmt::params::servercertfilepath)
  • servercustomsslcertificate (Any) (defaults to: $ilmt::params::servercustomsslcertificate)
  • tmpdir (Any) (defaults to: $ilmt::params::tmpdir)
  • useproxy (Any) (defaults to: $ilmt::params::useproxy)
  • version (Any) (defaults to: $ilmt::params::version) 


48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
 
# File 'manifests/init.pp', line 48

class ilmt (
  $ensure = $ilmt::params::ensure,
  $agentcert = $ilmt::params::agentcertfilepath,
  $agentcertfilepath = $ilmt::params::agentcertfilepath,
  $agenttemppath = $ilmt::params::agenttemppath,
  $citinstallpath = $ilmt::params::citinstallpath,
  $fipsenabled = $ilmt::params::fipsenabled,
  $installservercertificate = $ilmt::params::installservercertificate,
  $messagehandleraddress = $ilmt::params::messagehandleraddress,
  $package = $ilmt::params::package,
  $port = $ilmt::params::port,
  $proxyaddress = $ilmt::params::proxyaddress,
  $proxyport = $ilmt::params::proxyport,
  $scangroup = $ilmt::params::scangroup,
  $secureall = $ilmt::params::secureall,
  $secureauth = $ilmt::params::secureauth,
  $securitylevel = $ilmt::params::securitylevel,
  $servercert = $ilmt::params::servercert,
  $servercertfilepath = $ilmt::params::servercertfilepath,
  $servercustomsslcertificate = $ilmt::params::servercustomsslcertificate,
  $tmpdir = $ilmt::params::tmpdir,
  $useproxy = $ilmt::params::useproxy,
  $version = $ilmt::params::version
) inherits ilmt::params {

  # parameter validation
  validate_re(
    $ensure,
    '^((present|absent|disabled)|\d+(\.\d+)?)$',
    '$ensure must be "present", "absent", "disabled", or a version string.'
  )
  validate_re(
    $securitylevel,
    '^(0|1|2)$',
    '$securitylevel must be "0", "1", or "2".'
  )
  validate_absolute_path($agenttemppath)

  if ( $package ) {
    validate_string($package)
  }

  validate_string($port)
  validate_string($messagehandleraddress)
  validate_string($scangroup)

  validate_re($useproxy, '^(y|n)$', '$useproxy must be "y" or "n".')
  if ( str2bool($useproxy) ) {
    validate_re($proxyport, '^\d+$', '$proxyport must be a numeric port.')
    validate_string($proxyaddress)
  }

  validate_re($fipsenabled, '^(y|n)$', '$fipsenabled must be "y" or "n".')

  if ( $citinstallpath ) {
    validate_absolute_path($citinstallpath)
  }

  if ( $securitylevel > 0 ) {
    validate_string($secureauth)

    validate_re(
      $installservercertificate,
      '^(y|n)$',
      '$installservercertificate must be "y" or "n".'
    )
    validate_re(
      $servercustomsslcertificate,
      '^(y|n)$',
      '$servercustomsslcertificate must be "y" or "n".'
    )
    if (
      str2bool($installservercertificate) and
      str2bool($servercustomsslcertificate)
    ) {
      validate_absolute_path($servercertfilepath)
      validate_re(
        $servercertfilepath,
        'cert\.arm$',
        '$servercertfilepath must end in "cert.arm".'
      )
    }

    if ( $securitylevel > 1 ) {
      validate_string($secureall)
      validate_absolute_path($agentcertfilepath)
    }
  }

  # platform compatibility
  case $::osfamily {
    'RedHat': {
      $packagename = 'ILMT-TAD4D-agent'
      $package_filename = "${packagename}-${version}-linux-x86.rpm"
    }
    default: {
      fail("'${::osfamily}' platform is not supported.")
    }
  }

  File {
    owner   => 'root',
    group   => 'root',
    mode    => 0600,
  }

  $ilmt_package_provider = 'yum'

  $ensure_response_file = $ensure ? {
    'absent' => 'absent',
    default  => 'present',
  }
  file { 'response_file':
    ensure  => $ensure_response_file,
    path    => '/etc/response_file.txt',
    content => template('ilmt/response_file.txt.erb'),
  }

  if ( $package ) {
    $ilmt_package_source = "${tmpdir}/${package_filename}"
    $ensure_package_file = $ensure ? {
      'absent' => 'absent',
      default  => 'present',
    }
    file { 'package_file':
      ensure => $ensure_package_file,
      path   => $ilmt_package_source,
      source => $package,
      before => Package['ilmt_package'],
    }
  }
  else {
    $ilmt_package_source = undef
  }

  $ensure_ilmt_package = $ensure ? {
    'disabled' => 'present',
    default    => $ensure,
  }
  package { 'ilmt_package':
    ensure   => $ensure_ilmt_package,
    name     => $packagename,
    require  => File['response_file'],
    provider => $ilmt_package_provider,
    source   => $ilmt_package_source,
  }

  $ensure_ilmt_service = $ensure ? {
    'absent'   => 'stopped',
    'disabled' => 'stopped',
    default    => 'running',
  }
  $ensure_ilmt_service_enable = $ensure ? {
    'present' => true,
    default   => false
  }
  service { 'ilmt_service':
    ensure     => $ensure_ilmt_service,
    name       => 'tlm',
    require    => Package['ilmt_package'],
    subscribe  => Package['ilmt_package'],
    enable     => $ensure_ilmt_service_enable,
    hasrestart => false
  }

  if ( $securitylevel > 0 ) {
    class { 'ilmt::security':
      securitylevel      => $securitylevel,
      servercert         => $servercert,
      servercertfilepath => $servercertfilepath,
      agentcert          => $agentcert,
      agentcertfilepath  => $agentcertfilepath,
      before             => Package['ilmt_package'],
    }
  }
}