Puppet Class: icinga2::install

Defined in:
manifests/install.pp

Summary

This class handles the installation of the Icinga 2 package. On Windows only chocolatey is supported as installation source.

Overview



7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
 
# File 'manifests/install.pp', line 7

class icinga2::install {
  assert_private()

  $package_name         = $icinga2::globals::package_name
  $manage_packages      = $icinga2::manage_packages
  $selinux_package_name = $icinga2::globals::selinux_package_name
  $manage_selinux       = $icinga2::manage_selinux
  $cert_dir             = $icinga2::globals::cert_dir
  $conf_dir             = $icinga2::globals::conf_dir
  $user                 = $icinga2::globals::user
  $group                = $icinga2::globals::group

  if $manage_packages {
    if $facts['os']['family'] == 'windows' { Package { provider => chocolatey, } }

    package { $package_name:
      ensure => installed,
      before => File[$cert_dir, $conf_dir],
    }

    if str2bool($manage_selinux) and $selinux_package_name {
      package { $selinux_package_name:
        ensure  => installed,
        require => Package[$package_name],
      }
    }
  }

  file { [$conf_dir, $cert_dir]:
    ensure => directory,
    owner  => $user,
    group  => $group,
  }
}