Puppet Class: heat::keystone::auth

Defined in:
manifests/keystone/auth.pp

Overview

manage_heat_stack_user_role

(Optional) If true, this will manage the Keystone role for $heat_stack_user_role. Defaults to true

Examples

class { 'heat::keystone::auth':
  public_url   => 'https://10.0.0.10:8004/v1/%(tenant_id)s',
  internal_url => 'https://10.0.0.11:8004/v1/%(tenant_id)s',
  admin_url    => 'https://10.0.0.11:8004/v1/%(tenant_id)s',
}

Parameters:

  • password (Any) (defaults to: false)
  • email (Any) (defaults to: 'heat@localhost')
  • auth_name (Any) (defaults to: 'heat')
  • service_name (Any) (defaults to: 'heat')
  • service_type (Any) (defaults to: 'orchestration')
  • service_description (Any) (defaults to: 'Openstack Orchestration Service')
  • region (Any) (defaults to: 'RegionOne')
  • tenant (Any) (defaults to: 'services')
  • configure_endpoint (Any) (defaults to: true)
  • configure_service (Any) (defaults to: true)
  • configure_user (Any) (defaults to: true)
  • configure_user_role (Any) (defaults to: true)
  • trusts_delegated_roles (Any) (defaults to: ['heat_stack_owner'])
  • configure_delegated_roles (Any) (defaults to: false)
  • public_url (Any) (defaults to: 'http://127.0.0.1:8004/v1/%(tenant_id)s')
  • admin_url (Any) (defaults to: 'http://127.0.0.1:8004/v1/%(tenant_id)s')
  • internal_url (Any) (defaults to: 'http://127.0.0.1:8004/v1/%(tenant_id)s')
  • heat_stack_user_role (Any) (defaults to: 'heat_stack_user')
  • manage_heat_stack_user_role (Any) (defaults to: true) 


99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
 
# File 'manifests/keystone/auth.pp', line 99

class heat::keystone::auth (
  $password                    = false,
  $email                       = 'heat@localhost',
  $auth_name                   = 'heat',
  $service_name                = 'heat',
  $service_type                = 'orchestration',
  $service_description         = 'Openstack Orchestration Service',
  $region                      = 'RegionOne',
  $tenant                      = 'services',
  $configure_endpoint          = true,
  $configure_service           = true,
  $configure_user              = true,
  $configure_user_role         = true,
  $trusts_delegated_roles      = ['heat_stack_owner'],
  $configure_delegated_roles   = false,
  $public_url                  = 'http://127.0.0.1:8004/v1/%(tenant_id)s',
  $admin_url                   = 'http://127.0.0.1:8004/v1/%(tenant_id)s',
  $internal_url                = 'http://127.0.0.1:8004/v1/%(tenant_id)s',
  $heat_stack_user_role        = 'heat_stack_user',
  $manage_heat_stack_user_role = true,
) {

  include heat::deps

  validate_legacy(String, 'validate_string', $password)

  keystone::resource::service_identity { 'heat':
    configure_user      => $configure_user,
    configure_user_role => $configure_user_role,
    configure_endpoint  => $configure_endpoint,
    configure_service   => $configure_service,
    service_type        => $service_type,
    service_description => $service_description,
    service_name        => $service_name,
    region              => $region,
    auth_name           => $auth_name,
    password            => $password,
    email               => $email,
    tenant              => $tenant,
    public_url          => $public_url,
    admin_url           => $admin_url,
    internal_url        => $internal_url,
  }

  if $configure_user_role {
    Keystone_user_role["${auth_name}@${tenant}"] ~> Anchor['heat::service::end']
  }

  if $manage_heat_stack_user_role {
    keystone_role { $heat_stack_user_role:
      ensure => present,
    }
  }

  if $configure_delegated_roles {
    # if this is a keystone only node, we configure the role here
    # but let engine.pp set the config file. A keystone only node
    # will not have a heat.conf file.
    keystone_role { $trusts_delegated_roles:
      ensure => present,
    }
  }
}