Puppet Class: collectd::plugin::dbi

Defined in:
manifests/plugin/dbi.pp

Overview

collectd.org/wiki/index.php/Plugin:DBI

Parameters:

  • ensure (Any) (defaults to: 'present')
  • databases (Any) (defaults to: {})
  • queries (Any) (defaults to: {})
  • packages (Any) (defaults to: undef)
  • interval (Any) (defaults to: undef)
  • manage_package (Any) (defaults to: undef)
[View source]

2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
 
# File 'manifests/plugin/dbi.pp', line 2

class collectd::plugin::dbi (
  $ensure         = 'present',
  $databases      = {},
  $queries        = {},
  $packages       = undef,
  $interval       = undef,
  $manage_package = undef,
) {
  include collectd

  $_manage_package = pick($manage_package, $collectd::manage_package)

  $_databases_defaults = {
    'ensure' => $ensure,
  }

  $_queries_defaults   = {
    'ensure' => $ensure,
  }

  if $facts['os']['family'] == 'RedHat' {
    if $_manage_package {
      package { 'collectd-dbi':
        ensure => $ensure,
      }
    }
  }

  #manage additional packages such like db driver: libdbi-mysql
  if $packages {
    package { $packages:
      ensure => $ensure,
    }
  }

  collectd::plugin { 'dbi':
    ensure   => $ensure,
    interval => $interval,
  }

  concat { "${collectd::plugin_conf_dir}/dbi-config.conf":
    ensure         => $ensure,
    mode           => $collectd::config_mode,
    owner          => $collectd::config_owner,
    group          => $collectd::config_group,
    notify         => Service[$collectd::service_name],
    ensure_newline => true,
  }

  concat::fragment { 'collectd_plugin_dbi_conf_header':
    order   => '00',
    content => '<Plugin dbi>',
    target  => "${collectd::plugin_conf_dir}/dbi-config.conf",
  }

  concat::fragment { 'collectd_plugin_dbi_conf_footer':
    order   => '99',
    content => '</Plugin>',
    target  => "${collectd::plugin_conf_dir}/dbi-config.conf",
  }

  $databases.each |String $resource, Hash $attributes| {
    collectd::plugin::dbi::database { $resource:
      * => $_databases_defaults + $attributes,
    }
  }

  $queries.each |String $resource, Hash $attributes| {
    collectd::plugin::dbi::query { $resource:
      * => $_queries_defaults + $attributes,
    }
  }
}