Puppet Class: collectd::plugin::redis

Defined in:
manifests/plugin/redis.pp

Overview

collectd.org/wiki/index.php/Plugin:Redis

Parameters:

  • ensure (Enum['present', 'absent']) (defaults to: 'present')
  • interval (Optional[Integer[0]]) (defaults to: undef)
  • manage_package (Optional[Boolean]) (defaults to: undef)
  • nodes (Hash[String[1], Collectd::Redis::Node]) (defaults to: { 'redis' => { 'host' => 'localhost', 'port' => 6379, 'timeout' => 2000, 'queries' => { 'dbsize' => { 'type' => 'count', 'query' => 'DBSIZE', }, }, }, }) 


2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
 
# File 'manifests/plugin/redis.pp', line 2

class collectd::plugin::redis (
  Enum['present', 'absent']              $ensure         = 'present',
  Optional[Integer[0]]                   $interval       = undef,
  Optional[Boolean]                      $manage_package = undef,
  Hash[String[1], Collectd::Redis::Node] $nodes          = {
    'redis' => {
      'host'    => 'localhost',
      'port'    => 6379,
      'timeout' => 2000,
      'queries' => {
        'dbsize' => {
          'type'  => 'count',
          'query' => 'DBSIZE',
        },
      },
    },
  },
) {
  include collectd

  $_manage_package = pick($manage_package, $collectd::manage_package)

  if $facts['os']['family'] == 'RedHat' {
    if $_manage_package {
      package { 'collectd-redis':
        ensure => $ensure,
      }
    }
  }

  collectd::plugin { 'redis':
    ensure   => $ensure,
    content  => template('collectd/plugin/redis.conf.erb'),
    interval => $interval,
  }
}