Puppet Class: collectd::plugin::snmp

Defined in:
manifests/plugin/snmp.pp

Overview

collectd.org/wiki/index.php/Plugin:SNMP

Parameters:

  • ensure (Enum['present', 'absent']) (defaults to: 'present')
  • manage_package (Optional[Boolean]) (defaults to: undef)
  • data (Hash[String[1], Collectd::SNMP::Data]) (defaults to: {})
  • hosts (Hash[String[1], Collectd::SNMP::Host]) (defaults to: {})
  • interval (Optional[Integer[0]]) (defaults to: undef) 


2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
 
# File 'manifests/plugin/snmp.pp', line 2

class collectd::plugin::snmp (
  Enum['present', 'absent']             $ensure         = 'present',
  Optional[Boolean]                     $manage_package = undef,
  Hash[String[1], Collectd::SNMP::Data] $data           = {},
  Hash[String[1], Collectd::SNMP::Host] $hosts          = {},
  Optional[Integer[0]]                  $interval       = undef,
) {
  include collectd

  $_manage_package = pick($manage_package, $collectd::manage_package)

  if $facts['os']['family'] == 'RedHat' {
    if $_manage_package {
      package { 'collectd-snmp':
        ensure => $ensure,
      }
    }
  }

  collectd::plugin { 'snmp':
    ensure   => $ensure,
    content  => template('collectd/plugin/snmp.conf.erb'),
    interval => $interval,
  }
}