Puppet Class: icinga2::feature::compatlog

Defined in:
manifests/feature/compatlog.pp

Summary

Configures the Icinga 2 feature compatlog.

Overview

Parameters:

  • ensure (Enum['absent', 'present']) (defaults to: present) —

    Set to present enables the feature compatlog, absent disabled it.

  • log_dir (Optional[Stdlib::Absolutepath]) (defaults to: undef) —

    Absolute path to the log directory.

  • rotation_method (Optional[Enum['DAILY', 'HOURLY', 'MONTHLY', 'WEEKLY']]) (defaults to: undef) —

    Sets how often should the log file be rotated.



13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
 
# File 'manifests/feature/compatlog.pp', line 13

class icinga2::feature::compatlog (
  Enum['absent', 'present']                                 $ensure          = present,
  Optional[Stdlib::Absolutepath]                            $log_dir         = undef,
  Optional[Enum['DAILY', 'HOURLY', 'MONTHLY', 'WEEKLY']]    $rotation_method = undef,
) {
  if ! defined(Class['icinga2']) {
    fail('You must include the icinga2 base class before using any icinga2 feature class!')
  }

  $conf_dir = $icinga2::globals::conf_dir
  $_notify  = $ensure ? {
    'present' => Class['icinga2::service'],
    default   => undef,
  }

  # compose attributes
  $attrs = {
    'log_dir'         => $log_dir,
    'rotation_method' => $rotation_method,
  }

  # create object
  icinga2::object { 'icinga2::object::CompatLogger::compatlog':
    object_name => 'compatlog',
    object_type => 'CompatLogger',
    attrs       => delete_undef_values($attrs),
    attrs_list  => keys($attrs),
    target      => "${conf_dir}/features-available/compatlog.conf",
    order       => 10,
    notify      => $_notify,
  }

  # manage feature
  icinga2::feature { 'compatlog':
    ensure => $ensure,
  }
}