84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
|
# File 'manifests/feature/idopgsql.pp', line 84
class icinga2::feature::idopgsql (
Enum['absent', 'present'] $ensure = present,
Stdlib::Host $host = 'localhost',
Optional[Stdlib::Port] $port = undef,
String[1] $user = 'icinga',
String[1] $database = 'icinga',
Optional[Icinga::Secret] $password = undef,
Optional[Enum['disable', 'allow', 'prefer',
'verify-full', 'verify-ca', 'require']] $ssl_mode = undef,
Optional[Stdlib::Absolutepath] $ssl_key_path = undef,
Optional[Stdlib::Absolutepath] $ssl_cert_path = undef,
Optional[Stdlib::Absolutepath] $ssl_cacert_path = undef,
Optional[Icinga::Secret] $ssl_key = undef,
Optional[String[1]] $ssl_cert = undef,
Optional[String[1]] $ssl_cacert = undef,
Optional[String[1]] $table_prefix = undef,
Optional[String[1]] $instance_name = undef,
Optional[String[1]] $instance_description = undef,
Optional[Boolean] $enable_ha = undef,
Optional[Icinga2::Interval] $failover_timeout = undef,
Optional[Icinga2::IdoCleanup] $cleanup = undef,
Optional[Array] $categories = undef,
Boolean $import_schema = false,
) {
if ! defined(Class['icinga2']) {
fail('You must include the icinga2 base class before using any icinga2 feature class!')
}
$owner = $icinga2::globals::user
$group = $icinga2::globals::group
$conf_dir = $icinga2::globals::conf_dir
$ssl_dir = $icinga2::globals::cert_dir
$ido_pgsql_package_name = $icinga2::globals::ido_pgsql_package_name
$ido_pgsql_schema = $icinga2::globals::ido_pgsql_schema
$manage_packages = $icinga2::manage_packages
$enable_ssl = if $ssl_mode and $ssl_mode != 'disabled' {
true
} else {
false
}
$_notify = $ensure ? {
'present' => Class['icinga2::service'],
default => undef,
}
if $enable_ssl {
$cert = icinga::cert::files(
'IdoPgsqlConnection_ido-pgsql',
$ssl_dir,
$ssl_key_path,
$ssl_cert_path,
$ssl_cacert_path,
$ssl_key,
$ssl_cert,
$ssl_cacert,
)
$attrs_ssl = {
'ssl_mode' => $ssl_mode,
'ssl_ca' => $cert['cacert_file'],
'ssl_cert' => $cert['cert_file'],
'ssl_key' => $cert['key_file'],
}
# Workaround, icinga::cert doesn't accept undef values for owner and group!
if $facts['os']['family'] != 'windows' {
icinga::cert { 'IdoPgsqlConnection_ido-pgsql':
args => $cert,
owner => $owner,
group => $group,
notify => $_notify,
}
} else {
icinga::cert { 'IdoPgsqlConnection_ido-pgsql':
args => $cert,
owner => 'foo',
group => 'bar',
notify => $_notify,
}
}
} else {
$attrs_ssl = {
'ssl_mode' => undef,
'ssl_ca' => undef,
'ssl_cert' => undef,
'ssl_key' => undef,
}
$cert = {}
}
$attrs = {
'host' => $host,
'port' => $port,
'user' => $user,
'password' => Sensitive($password),
'database' => $database,
'table_prefix' => $table_prefix,
'instance_name' => $instance_name,
'instance_description' => $instance_description,
'enable_ha' => $enable_ha,
'failover_timeout' => $failover_timeout,
'cleanup' => $cleanup,
'categories' => $categories,
}
# install additional package
if $ido_pgsql_package_name and $manage_packages {
if $facts['os']['family'] == 'debian' {
ensure_resources('file', { '/etc/dbconfig-common' => { ensure => directory, owner => 'root', group => 'root' } })
file { "/etc/dbconfig-common/${ido_pgsql_package_name}.conf":
ensure => file,
content => "dbc_install='false'\ndbc_upgrade='false'\ndbc_remove='false'\n",
owner => 'root',
group => 'root',
mode => '0600',
before => Package[$ido_pgsql_package_name],
}
} # Debian
package { $ido_pgsql_package_name:
ensure => installed,
before => Icinga2::Feature['ido-pgsql'],
}
}
# import db schema
if $import_schema {
if $ido_pgsql_package_name and $manage_packages {
Package[$ido_pgsql_package_name] -> Exec['idopgsql-import-schema']
}
$db_cli_options = icinga::db::connect({
'type' => 'pgsql',
'host' => $host,
'port' => $port,
'database' => $database,
'username' => $user,
}, $cert, $enable_ssl, $ssl_mode)
exec { 'idopgsql-import-schema':
user => 'root',
path => $facts['path'],
environment => [sprintf('PGPASSWORD=%s', unwrap($password))],
command => "psql '${db_cli_options}' -w -f '${ido_pgsql_schema}'",
unless => "psql '${db_cli_options}' -w -c 'select version from icinga_dbversion'",
}
}
# create object
icinga2::object { 'icinga2::object::IdoPgsqlConnection::ido-pgsql':
object_name => 'ido-pgsql',
object_type => 'IdoPgsqlConnection',
attrs => delete_undef_values($attrs + $attrs_ssl),
attrs_list => concat(keys($attrs), keys($attrs_ssl)),
target => "${conf_dir}/features-available/ido-pgsql.conf",
order => 10,
notify => $_notify,
}
icinga2::feature { 'ido-pgsql':
ensure => $ensure,
}
}
|