81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
|
# File 'manifests/feature/influxdb2.pp', line 81
class icinga2::feature::influxdb2 (
String[1] $organization,
String[1] $bucket,
Icinga::Secret $auth_token,
Enum['absent', 'present'] $ensure = present,
Optional[Stdlib::Host] $host = undef,
Optional[Stdlib::Port] $port = undef,
Optional[Boolean] $enable_ssl = undef,
Optional[Boolean] $ssl_noverify = undef,
Optional[Stdlib::Absolutepath] $ssl_key_path = undef,
Optional[Stdlib::Absolutepath] $ssl_cert_path = undef,
Optional[Stdlib::Absolutepath] $ssl_cacert_path = undef,
Optional[Icinga::Secret] $ssl_key = undef,
Optional[String[1]] $ssl_cert = undef,
Optional[String[1]] $ssl_cacert = undef,
String[1] $host_measurement = '$host.check_command$',
Hash[String[1], String[1]] $host_tags = { hostname => '$host.name$' },
String[1] $service_measurement = '$service.check_command$',
Hash[String[1], String[1]] $service_tags = { hostname => '$host.name$', service => '$service.name$' },
Optional[Boolean] $enable_send_thresholds = undef,
Optional[Boolean] $enable_send_metadata = undef,
Optional[Icinga2::Interval] $flush_interval = undef,
Optional[Integer[1]] $flush_threshold = undef,
Optional[Boolean] $enable_ha = undef,
) {
if ! defined(Class['icinga2']) {
fail('You must include the icinga2 base class before using any icinga2 feature class!')
}
$owner = $icinga2::globals::user
$group = $icinga2::globals::group
$conf_dir = $icinga2::globals::conf_dir
$ssl_dir = $icinga2::globals::cert_dir
$_notify = $ensure ? {
'present' => Class['icinga2::service'],
default => undef,
}
$host_template = { measurement => $host_measurement, tags => $host_tags }
$service_template = { measurement => $service_measurement, tags => $service_tags }
if $enable_ssl {
$cert = icinga::cert::files(
'Influxdb2Writer_influxdb2',
$ssl_dir,
$ssl_key_path,
$ssl_cert_path,
$ssl_cacert_path,
$ssl_key,
$ssl_cert,
$ssl_cacert,
)
$attrs_ssl = {
'ssl_enable' => true,
'ssl_insecure_noverify' => $ssl_noverify,
'ssl_ca_cert' => $cert['cacert_file'],
'ssl_cert' => $cert['cert_file'],
'ssl_key' => $cert['key_file'],
}
# Workaround, icinga::cert doesn't accept undef values for owner and group!
if $facts['os']['family'] != 'windows' {
icinga::cert { 'Influxdb2Writer_influxdb2':
args => $cert,
owner => $owner,
group => $group,
notify => $_notify,
}
} else {
icinga::cert { 'Influxdb2Writer_influxdb2':
args => $cert,
owner => 'foo',
group => 'bar',
notify => $_notify,
}
}
} else {
$attrs_ssl = {
'ssl_enable' => undef,
'ssl_insecure_noverify' => undef,
'ssl_ca_cert' => undef,
'ssl_cert' => undef,
'ssl_key' => undef,
}
$cert = {}
}
$attrs = {
'host' => $host,
'port' => $port,
'organization' => $organization,
'bucket' => $bucket,
'auth_token' => Sensitive($auth_token),
'host_template' => $host_template,
'service_template' => $service_template,
'enable_send_thresholds' => $enable_send_thresholds,
'enable_send_metadata' => $enable_send_metadata,
'flush_interval' => $flush_interval,
'flush_threshold' => $flush_threshold,
'enable_ha' => $enable_ha,
}
# create object
icinga2::object { 'icinga2::object::Influxdb2Writer::influxdb2':
object_name => 'influxdb2',
object_type => 'Influxdb2Writer',
attrs => delete_undef_values($attrs + $attrs_ssl),
attrs_list => concat(keys($attrs), keys($attrs_ssl)),
target => "${conf_dir}/features-available/influxdb2.conf",
notify => $_notify,
order => 10,
}
icinga2::feature { 'influxdb2':
ensure => $ensure,
}
}
|