Puppet Class: jenkins::slave

Inherits:
jenkins::params
Defined in:
manifests/slave.pp

Overview

Examples

class { 'jenkins::slave':
  masterurl => 'http://jenkins-master1.example.com:8080',
  ui_user => 'adminuser',
  ui_pass => 'adminpass'
}

Authors

Matthew Barr <mbarr@mbarr.net>

Copyright 2013 Matthew Barr , but can be used for anything by anyone..

Parameters:

  • slave_name (Optional[String]) (defaults to: undef)
  • description (Optional[String]) (defaults to: undef)
  • masterurl (Optional[String]) (defaults to: undef)
  • autodiscoveryaddress (Optional[String]) (defaults to: undef)
  • ui_user (Optional[String]) (defaults to: undef)
  • ui_pass (Optional[String]) (defaults to: undef)
  • tool_locations (Optional[String]) (defaults to: undef)
  • source (Optional[String]) (defaults to: undef)
  • proxy_server (Optional[String]) (defaults to: undef)
  • tunnel (Optional[Jenkins::Tunnel]) (defaults to: undef)
  • version (String) (defaults to: $jenkins::params::swarm_version)
  • executors (Integer) (defaults to: 2)
  • manage_slave_user (Boolean) (defaults to: true)
  • slave_user (String) (defaults to: 'jenkins-slave')
  • slave_groups (Optional[String]) (defaults to: undef)
  • slave_uid (Optional[Integer]) (defaults to: undef)
  • slave_home (Stdlib::Absolutepath) (defaults to: '/home/jenkins-slave')
  • slave_mode (Enum['normal', 'exclusive']) (defaults to: 'normal')
  • disable_ssl_verification (Boolean) (defaults to: false)
  • disable_clients_unique_id (Boolean) (defaults to: false)
  • labels (Array[String[1]]) (defaults to: [])
  • install_java (Any) (defaults to: true)
  • manage_client_jar (Boolean) (defaults to: true)
  • ensure (Enum['running', 'stopped']) (defaults to: 'running')
  • enable (Boolean) (defaults to: true)
  • java_args (Array[String[1]]) (defaults to: [])
  • swarm_client_args (Array[String[1]]) (defaults to: [])
  • delete_existing_clients (Boolean) (defaults to: false)
  • java_cmd (Any) (defaults to: '/usr/bin/java') 


116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
 
# File 'manifests/slave.pp', line 116

class jenkins::slave (
  Optional[String] $slave_name            = undef,
  Optional[String] $description           = undef,
  Optional[String] $masterurl             = undef,
  Optional[String] $autodiscoveryaddress  = undef,
  Optional[String] $ui_user               = undef,
  Optional[String] $ui_pass               = undef,
  Optional[String] $tool_locations        = undef,
  Optional[String] $source                = undef,
  Optional[String] $proxy_server          = undef,
  Optional[Jenkins::Tunnel] $tunnel       = undef,
  String $version                         = $jenkins::params::swarm_version,
  Integer $executors                      = 2,
  Boolean $manage_slave_user              = true,
  String $slave_user                      = 'jenkins-slave',
  Optional[String] $slave_groups          = undef,
  Optional[Integer] $slave_uid            = undef,
  Stdlib::Absolutepath $slave_home        = '/home/jenkins-slave',
  Enum['normal', 'exclusive'] $slave_mode = 'normal',
  Boolean $disable_ssl_verification       = false,
  Boolean $disable_clients_unique_id      = false,
  Array[String[1]] $labels                = [],
  Any $install_java                       = true,
  Boolean $manage_client_jar              = true,
  Enum['running', 'stopped'] $ensure      = 'running',
  Boolean $enable                         = true,
  Array[String[1]] $java_args             = [],
  Array[String[1]] $swarm_client_args     = [],
  Boolean $delete_existing_clients        = false,
  Any $java_cmd                           = '/usr/bin/java',
) inherits jenkins::params {
  if versioncmp($version, '3.0') < 0 {
    $client_jar = "swarm-client-${version}-jar-with-dependencies.jar"
  } else {
    $client_jar = "swarm-client-${version}.jar"
  }

  $client_url = $source ? {
    undef   => "https://repo.jenkins-ci.org/releases/org/jenkins-ci/plugins/swarm-client/${version}/",
    default => $source,
  }
  $quoted_ui_user = shellquote($ui_user)
  $quoted_ui_pass = shellquote($ui_pass)

  # the "public" API for tool_locations is a space seperated string in the
  # format "<name>:<path> [<name>:<path> ...]"
  # XXX a hash would be a more reasonable interface
  $_real_tool_locations = $tool_locations ? {
    undef   => undef,
    default => regsubst($tool_locations, ':', '=', 'G'),
  }

  if $install_java and ($facts['os']['family'] != 'Darwin') {
    # Currently the puppetlabs/java module doesn't support installing Java on
    # Darwin
    include java
    Class['java'] -> Service['jenkins-slave']
  }

  case $facts['kernel'] {
    'Linux': {
      $service_name     = 'jenkins-slave'
      $defaults_user    = 'root'
      $defaults_group   = 'root'
      $manage_user_home = true

      $defaults_location = $facts['os']['family'] ? {
        'Archlinux' => '/etc/conf.d',
        'Debian'    => '/etc/default',
        default     => '/etc/sysconfig',
      }

      file { "${defaults_location}/jenkins-slave":
        ensure  => 'file',
        mode    => '0600',
        owner   => $defaults_user,
        group   => $defaults_group,
        content => template("${module_name}/jenkins-slave-defaults.erb"),
        notify  => Service['jenkins-slave'],
      }

      file { "${slave_home}/${service_name}-run":
        content => template("${module_name}/${service_name}-run.erb"),
        owner   => $slave_user,
        mode    => '0755',
        seltype => 'bin_t',
        notify  => Service[$service_name],
      }

      systemd::unit_file { "${service_name}.service":
        content => template("${module_name}/${service_name}.service.erb"),
        notify  => Service[$service_name],
      }
    }
    'Darwin': {
      $service_name     = 'org.jenkins-ci.slave.jnlp'
      $defaults_user    = 'jenkins'
      $defaults_group   = 'wheel'
      $manage_user_home = false

      file { '/Library/LaunchDaemons/org.jenkins-ci.slave.jnlp.plist':
        ensure  => 'file',
        content => template("${module_name}/org.jenkins-ci.slave.jnlp.plist.epp"),
        mode    => '0644',
        owner   => 'root',
        group   => 'wheel',
      }
      -> Service['jenkins-slave']

      file { '/var/log/jenkins':
        ensure => 'directory',
        owner  => $slave_user,
      }
      -> Service['jenkins-slave']

      if $manage_slave_user {
        # osx doesn't have managehome support, so create directory
        file { $slave_home:
          ensure  => directory,
          mode    => '0755',
          owner   => $slave_user,
          require => User['jenkins-slave_user'],
        }
      }
    }
    default: {}
  }

  #a Add jenkins slave user if necessary.
  if $manage_slave_user {
    user { 'jenkins-slave_user':
      ensure     => present,
      name       => $slave_user,
      comment    => 'Jenkins Slave user',
      home       => $slave_home,
      managehome => $manage_user_home,
      system     => true,
      uid        => $slave_uid,
      groups     => $slave_groups,
    }
  }

  if ($manage_client_jar) {
    archive { 'get_swarm_client':
      source       => "${client_url}/${client_jar}",
      path         => "${slave_home}/${client_jar}",
      proxy_server => $proxy_server,
      cleanup      => false,
      extract      => false,
    }
    -> Service['jenkins-slave']
  }

  service { 'jenkins-slave':
    ensure     => $ensure,
    name       => $service_name,
    enable     => $enable,
    hasstatus  => true,
    hasrestart => true,
  }

  if $manage_slave_user and $manage_client_jar {
    User['jenkins-slave_user']
    -> Archive['get_swarm_client']
  }
}