Puppet Class: kibana::install

Defined in:
manifests/install.pp

Overview

This class is called from the kibana class to manage installation. It is not meant to be called directly.

Author:

  • Tyler Langlois <tyler.langlois@elastic.co>



6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
 
# File 'manifests/install.pp', line 6

class kibana::install {
  if $kibana::manage_repo {
    if $facts['os']['family'] == 'Debian' {
      include apt
      Class['apt::update'] -> Package['kibana']
    }
  }

  if $kibana::package_source != undef {
    case $facts['os']['family'] {
      'Debian': { Package['kibana'] { provider => 'dpkg' } }
      'RedHat': { Package['kibana'] { provider => 'rpm' } }
      default: { fail("unsupported parameter 'source' set for osfamily ${facts['os']['family']}") }
    }
  }

  $_oss = $kibana::oss ? {
    true    => '-oss',
    default => '',
  }

  package { 'kibana':
    ensure => $kibana::ensure,
    name   => "${kibana::package_name}${_oss}",
    source => $kibana::package_source,
  }
}