Puppet Class: mongodb::server
- Inherits:
- mongodb::globals
- Defined in:
- manifests/server.pp
Summary
This installs a MongoDB server.Overview
Most of the parameters manipulate the mongod.conf file.
For more details about configuration parameters consult the MongoDB Configuration File Options.
This setting can be used to specify if the service should be running.
306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485 486 487 |
# File 'manifests/server.pp', line 306
class mongodb::server (
String[1] $user,
String[1] $group,
Stdlib::Absolutepath $dbpath,
String[1] $ensure = 'present',
Stdlib::Absolutepath $config = '/etc/mongod.conf',
Boolean $dbpath_fix = false,
Optional[Stdlib::Absolutepath] $pidfilepath = undef,
String[4,4] $pidfilemode = '0644',
Boolean $manage_pidfile = false,
String $rcfile = "${facts['root_home']}/.mongoshrc.js",
Boolean $service_manage = true,
Optional[String[1]] $service_provider = undef,
String[1] $service_name = 'mongod',
Boolean $service_enable = true,
Enum['stopped', 'running'] $service_ensure = 'running',
Optional[Enum['stopped', 'running']] $service_status = undef,
String[1] $package_ensure = pick($mongodb::globals::version, 'present'),
String[1] $package_name = "mongodb-${mongodb::globals::edition}-server",
Stdlib::Absolutepath $logpath = '/var/log/mongodb/mongod.log',
Array[Stdlib::IP::Address] $bind_ip = ['127.0.0.1'],
Optional[Boolean] $ipv6 = undef,
Boolean $logappend = true,
Optional[String] $system_logrotate = undef,
Optional[Boolean] $fork = undef,
Optional[Integer[1, 65535]] $port = undef,
Optional[Boolean] $journal = undef,
Optional[Boolean] $smallfiles = undef,
Optional[Boolean] $cpu = undef,
Boolean $auth = false,
Optional[Boolean] $verbose = undef,
Optional[String] $verbositylevel = undef,
Optional[Boolean] $objcheck = undef,
Optional[Boolean] $quota = undef,
Optional[Integer] $quotafiles = undef,
Optional[Integer[0, 7]] $diaglog = undef,
Optional[Boolean] $directoryperdb = undef,
$profile = undef,
Optional[Integer] $maxconns = undef,
Optional[Integer] $oplog_size = undef,
$nohints = undef,
Optional[Boolean] $nohttpinterface = undef,
Optional[Boolean] $noscripting = undef,
Optional[Boolean] $notablescan = undef,
Optional[Boolean] $noprealloc = undef,
Optional[Integer] $nssize = undef,
$mms_token = undef,
$mms_name = undef,
$mms_interval = undef,
Optional[String] $replset = undef,
Optional[Hash] $replset_config = undef,
Optional[Array] $replset_members = undef,
Optional[Boolean] $configsvr = undef,
Optional[Boolean] $shardsvr = undef,
Optional[Boolean] $rest = undef,
Optional[Boolean] $quiet = undef,
Optional[Integer] $slowms = undef,
Optional[Stdlib::Absolutepath] $keyfile = undef,
Optional[Variant[String[6], Sensitive[String[6]]]] $key = undef,
Optional[Variant[String[1], Array[String[1]], Hash]] $set_parameter = undef,
Boolean $syslog = false,
$config_content = undef,
Optional[String] $config_template = undef,
Optional[Hash] $config_data = undef,
Boolean $tls = false,
Optional[Stdlib::Absolutepath] $tls_key = undef,
Optional[Stdlib::Absolutepath] $tls_ca = undef,
Optional[Boolean] $tls_conn_without_cert = undef,
Optional[Boolean] $tls_invalid_hostnames = undef,
Optional[Boolean] $tls_invalid_certificates = undef,
Enum['requireTLS', 'preferTLS', 'allowTLS'] $tls_mode = 'requireTLS',
Boolean $restart = true,
Optional[String] $storage_engine = undef,
Boolean $create_admin = false,
String $admin_username = 'admin',
Optional[Variant[String, Sensitive[String]]] $admin_password = undef,
Optional[Variant[String[1], Sensitive[String[1]]]] $admin_password_hash = undef,
Enum['scram_sha_1', 'scram_sha_256'] $admin_auth_mechanism = 'scram_sha_1',
Boolean $admin_update_password = false,
Boolean $handle_creds = true,
Boolean $store_creds = false,
Array[String[1]] $admin_roles = [
'userAdmin', 'readWrite', 'dbAdmin', 'dbAdminAnyDatabase', 'readAnyDatabase',
'readWriteAnyDatabase', 'userAdminAnyDatabase', 'clusterAdmin',
'clusterManager', 'clusterMonitor', 'hostManager', 'root', 'restore',
],
) inherits mongodb::globals {
if $journal != undef {
if $mongodb::globals::repo_location == undef {
$_repo_loc_version_match = undef
} else {
$_repo_loc_version_match = $mongodb::globals::repo_location.match(/[0-9]+\.[0-9]+/)
}
if (
$mongodb::globals::manage_package_repo
and $mongodb::globals::repo_location == undef
and versioncmp($mongodb::globals::repo_version, '7.0') >= 0
) or (
$mongodb::globals::manage_package_repo
and $mongodb::globals::repo_location != undef
and $_repo_loc_version_match != undef
and versioncmp($_repo_loc_version_match[0], '7.0') >= 0
) or (
$package_ensure =~ /\./ and versioncmp($package_ensure, '7.0.0') >= 0
) {
fail('`journal` parameter is only supported for MongoDB < 7.0')
}
}
contain mongodb::server::install
contain mongodb::server::config
contain mongodb::server::service
if ($ensure == 'present' or $ensure == true) {
Class['mongodb::server::install'] -> Class['mongodb::server::config']
if $restart {
# If $restart is true, notify the service on config changes (~>)
Class['mongodb::server::config'] ~> Class['mongodb::server::service']
} else {
# If $restart is false, config changes won't restart the service (->)
Class['mongodb::server::config'] -> Class['mongodb::server::service']
}
} else {
Class['mongodb::server::service'] -> Class['mongodb::server::config'] -> Class['mongodb::server::install']
}
$admin_password_unsensitive = if $admin_password =~ Sensitive[String] {
$admin_password.unwrap
} else {
$admin_password
}
if $create_admin and ($service_ensure == 'running' or $service_ensure == true) {
mongodb::db { 'admin':
user => $admin_username,
auth_mechanism => $admin_auth_mechanism,
password => $admin_password_unsensitive,
password_hash => $admin_password_hash,
roles => $admin_roles,
update_password => $admin_update_password,
}
# Make sure it runs before other DB creation
Mongodb::Db['admin'] -> Mongodb::Db <| title != 'admin' |>
}
# Set-up replicasets
if $replset {
# Check that we've got either a members array or a replset_config hash
if $replset_members and $replset_config {
fail('You can provide either replset_members or replset_config, not both.')
} elsif !$replset_members and !$replset_config {
# No members or config provided. Warn about it.
warning('Replset specified, but no replset_members or replset_config provided.')
} else {
if $replset_config {
# Copy it to REAL value
$_replset_config = $replset_config
} else {
# Build up a config hash
$_replset_config = {
"${replset}" => {
'ensure' => 'present',
'members' => $replset_members,
},
}
}
# Wrap the replset class
class { 'mongodb::replset':
sets => $_replset_config,
}
$replset_config_real = $_replset_config # lint:ignore:variable_is_lowercase required for compatibility
# Make sure that the ordering is correct
if $create_admin {
Class['mongodb::replset'] -> Mongodb::Db['admin']
}
}
}
}
|