Puppet Class: php::cli

Inherits:
php::params
Defined in:
manifests/cli.pp

Overview

Install and configure php CLI

Parameters

inifile

The path to the ini php5-cli ini file

settings

Hash with nested hash of key => value to set in inifile

Parameters:

  • inifile (Stdlib::Absolutepath) (defaults to: $php::params::cli_inifile)
  • settings (Hash) (defaults to: {}) 


11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
 
# File 'manifests/cli.pp', line 11

class php::cli (
  Stdlib::Absolutepath $inifile = $php::params::cli_inifile,
  Hash $settings                = {}
) inherits php::params {
  assert_private()

  if $php::globals::rhscl_mode {
    # stupid fixes for scl
    file { '/usr/bin/pear':
      ensure => 'link',
      target => "${$php::params::php_bin_dir}/pear",
    }

    file { '/usr/bin/pecl':
      ensure => 'link',
      target => "${$php::params::php_bin_dir}/pecl",
    }

    file { '/usr/bin/php':
      ensure => 'link',
      target => "${$php::params::php_bin_dir}/php",
    }
  }

  $real_settings = lookup('php::cli::settings', Hash, { 'strategy' => 'deep', 'merge_hash_arrays' => true }, $settings)

  if $inifile != $php::params::config_root_inifile {
    # only create a cli specific inifile if the filenames are different
    ::php::config { 'cli':
      file   => $inifile,
      config => $real_settings,
    }
  }
}