69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
|
# File 'manifests/node_exporter.pp', line 69
class prometheus::node_exporter (
String $download_extension,
Prometheus::Uri $download_url_base,
Array[String] $extra_groups,
String[1] $group,
String[1] $package_ensure,
String[1] $package_name,
String[1] $user,
String[1] $version,
Boolean $purge_config_dir = true,
Boolean $restart_on_change = true,
Boolean $service_enable = true,
Stdlib::Ensure::Service $service_ensure = 'running',
String[1] $service_name = 'node_exporter',
Prometheus::Initstyle $init_style = $prometheus::init_style,
Prometheus::Install $install_method = $prometheus::install_method,
Boolean $manage_group = true,
Boolean $manage_service = true,
Boolean $manage_user = true,
String[1] $os = downcase($facts['kernel']),
Optional[String[1]] $extra_options = undef,
Optional[Prometheus::Uri] $download_url = undef,
String[1] $arch = $prometheus::real_arch,
Stdlib::Absolutepath $bin_dir = $prometheus::bin_dir,
Optional[Array[String]] $collectors = undef,
Array[String] $collectors_enable = [],
Array[String] $collectors_disable = [],
Optional[Stdlib::Host] $scrape_host = undef,
Boolean $export_scrape_job = false,
Stdlib::Port $scrape_port = 9100,
String[1] $scrape_job_name = 'node',
Optional[Hash] $scrape_job_labels = undef,
Optional[String[1]] $bin_name = undef,
Hash[String[1], Scalar] $env_vars = {},
Stdlib::Absolutepath $env_file_path = $prometheus::env_file_path,
Optional[String[1]] $proxy_server = undef,
Optional[Enum['none', 'http', 'https', 'ftp']] $proxy_type = undef,
Stdlib::Absolutepath $web_config_file = '/etc/node_exporter_web-config.yml',
Prometheus::Web_config $web_config_content = {},
) inherits prometheus {
# Prometheus added a 'v' on the realease name at 0.13.0
if versioncmp ($version, '0.13.0') >= 0 {
$release = "v${version}"
} else {
$release = $version
}
$real_download_url = pick($download_url, "${download_url_base}/download/${release}/${package_name}-${version}.${os}-${arch}.${download_extension}")
if $collectors {
warning('Use of $collectors parameter is deprecated')
}
$notify_service = $restart_on_change ? {
true => Service[$service_name],
default => undef,
}
$cmd_collectors_enable = $collectors_enable.map |$collector| {
"--collector.${collector}"
}
$cmd_collectors_disable = $collectors_disable.map |$collector| {
"--no-collector.${collector}"
}
$_web_config_ensure = $web_config_content.empty ? {
true => absent,
default => file,
}
file { $web_config_file:
ensure => $_web_config_ensure,
owner => $user,
group => $group,
mode => '0640',
content => $web_config_content.stdlib::to_yaml,
notify => $notify_service,
}
$_web_config = if $web_config_content.empty {
''
} else {
if versioncmp($version, '1.5.0') >= 0 {
"--web.config.file=${$web_config_file}"
} else {
"--web.config=${$web_config_file}"
}
}
$options = [
$extra_options,
$cmd_collectors_enable.join(' '),
$cmd_collectors_disable.join(' '),
$_web_config,
].filter |$x| { !$x.empty }.join(' ')
prometheus::daemon { $service_name:
install_method => $install_method,
version => $version,
download_extension => $download_extension,
os => $os,
arch => $arch,
real_download_url => $real_download_url,
bin_dir => $bin_dir,
notify_service => $notify_service,
package_name => $package_name,
package_ensure => $package_ensure,
manage_user => $manage_user,
user => $user,
extra_groups => $extra_groups,
group => $group,
manage_group => $manage_group,
purge => $purge_config_dir,
options => $options,
init_style => $init_style,
service_ensure => $service_ensure,
service_enable => $service_enable,
manage_service => $manage_service,
export_scrape_job => $export_scrape_job,
scrape_host => $scrape_host,
scrape_port => $scrape_port,
scrape_job_name => $scrape_job_name,
scrape_job_labels => $scrape_job_labels,
bin_name => $bin_name,
env_vars => $env_vars,
env_file_path => $env_file_path,
proxy_server => $proxy_server,
proxy_type => $proxy_type,
}
}
|