Puppet Class: wildfly
- Defined in:
- manifests/init.pp
Overview
Main class, includes all other classes.
59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 |
# File 'manifests/init.pp', line 59
class wildfly (
Pattern[/^(\d{1,}\.\d{1,}(\.\d{1,})?$)/] $version = '9.0.2',
Variant[Pattern[/^file:\/\//],
Pattern[/^puppet:\/\//],
Stdlib::Httpsurl, Stdlib::Httpurl,
Undef
] $install_source = undef,
Wildfly::Distribution $distribution = 'wildfly',
Wildfly::Mode $mode = 'standalone',
Stdlib::Unixpath $dirname = '/opt/wildfly',
Stdlib::Unixpath $java_home = '/usr/java/default',
Stdlib::Unixpath $console_log = '/var/log/wildfly/console.log',
Stdlib::Unixpath $install_cache_dir = '/var/cache/wget',
Stdlib::Unixpath $deploy_cache_dir = '/opt',
Stdlib::Unixpath $mgmt_keystore = "${dirname}/${mode}/configuration/mgmt.jks",
Boolean $manage_user = true,
String $user = 'wildfly',
Stdlib::Unixpath $user_home = '/home/wildfly',
String $group = 'wildfly',
String $mode_template = "wildfly/${mode}.conf",
String $mgmt_keystore_pass = 'changeit',
String $mgmt_keystore_alias = 'mgmt',
Wildfly::Config_file $config = 'standalone.xml',
Wildfly::Config_file $domain_config = 'domain.xml',
Wildfly::Config_file $host_config = 'host.xml',
String $java_xmx = '512m',
String $java_xms = '256m',
String $java_maxmetaspace_size = '128m',
String $package_ensure = 'present',
Boolean $service_ensure = true,
Boolean $service_manage = true,
Boolean $service_enable = true,
Boolean $remote_debug = false,
Boolean $external_facts = false,
Boolean $secure_mgmt_api = false,
Boolean $mgmt_create_keystores = true,
Integer $remote_debug_port = 8787,
Integer $startup_wait = 30,
Integer $shutdown_wait = 30,
Integer $install_download_timeout = 500,
Hash[Pattern[/^\w*(\.\w*-?\w*)*$/], String] $properties = {
'jboss.bind.address' => '0.0.0.0',
'jboss.bind.address.management' => '127.0.0.1',
'jboss.management.http.port' => '9990',
'jboss.management.https.port' => '9993',
'jboss.http.port' => '8080',
'jboss.https.port' => '8443',
'jboss.ajp.port' => '8009',
},
Struct[{ username => String, password => String }] $mgmt_user = {
username => 'puppet',
password => fqdn_rand_string(30),
},
Optional[Stdlib::Unixpath] $conf_file = undef,
Optional[String] $conf_template = undef,
Optional[Stdlib::Unixpath] $service_file = undef,
Optional[String] $systemd_template = undef,
Optional[String] $service_name = undef,
Optional[String] $custom_init = undef,
Optional[Integer] $uid = undef,
Optional[Integer] $gid = undef,
Optional[String] $secret_value = undef,
Optional[String] $remote_username = undef,
Optional[String] $package_name = undef,
Optional[String] $package_version = undef,
Variant[Undef, String, Array] $java_opts = undef,
Variant[Undef, String, Array] $process_controller_java_opts = undef,
Variant[Undef, String, Array] $host_controller_java_opts = undef,
Optional[String] $jboss_opts = undef,
Optional[String] $overlay_class = undef,
Optional[Stdlib::Unixpath] $mgmt_ssl_cert = undef,
Optional[Stdlib::Unixpath] $mgmt_ssl_key = undef,
) {
contain wildfly::prepare
contain wildfly::install
contain wildfly::setup
contain wildfly::service
if $overlay_class {
contain $overlay_class
Class['wildfly::install']
-> Class[$overlay_class]
-> Class['wildfly::setup']
}
if $external_facts {
contain wildfly::external_facts
Class['wildfly::external_facts']
-> Class['wildfly::install']
}
if $secure_mgmt_api {
include wildfly::secure_mgmt_api
}
Class['wildfly::prepare']
-> Class['wildfly::install']
-> Class['wildfly::setup']
-> Class['wildfly::service']
}
|