Puppet Class: apache::mod::info

Defined in:
manifests/mod/info.pp

Summary

Installs and configures `mod_info`.

Overview

Parameters:

  • allow_from (Array[Stdlib::IP::Address]) (defaults to: ['127.0.0.1', '::1']) —

    Allowlist of IPv4 or IPv6 addresses or ranges that can access the info path.

  • apache_version (Optional[String]) (defaults to: undef) —

    Version of Apache to install module on.

  • restrict_access (Boolean) (defaults to: true) —

    Toggles whether to restrict access to info path. If ‘false`, the `allow_from` allowlist is ignored and any IP address can access the info path.

  • info_path (Stdlib::Unixpath) (defaults to: '/server-info') —

    Path on server to file containing server configuration information.

See Also:



19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
 
# File 'manifests/mod/info.pp', line 19

class apache::mod::info (
  Array[Stdlib::IP::Address] $allow_from = ['127.0.0.1', '::1'],
  Optional[String] $apache_version       = undef,
  Boolean $restrict_access               = true,
  Stdlib::Unixpath $info_path            = '/server-info',
) {
  include apache
  $_apache_version = pick($apache_version, $apache::apache_version)

  if $facts['os']['family'] == 'Suse' {
    if defined(Class['apache::mod::worker']) {
      $suse_path = '/usr/lib64/apache2-worker'
    } else {
      $suse_path = '/usr/lib64/apache2-prefork'
    }
    ::apache::mod { 'info':
      lib_path => $suse_path,
    }
  } else {
    ::apache::mod { 'info': }
  }

  # Template uses $allow_from, $_apache_version
  file { 'info.conf':
    ensure  => file,
    path    => "${apache::mod_dir}/info.conf",
    mode    => $apache::file_mode,
    content => template('apache/mod/info.conf.erb'),
    require => Exec["mkdir ${apache::mod_dir}"],
    before  => File[$apache::mod_dir],
    notify  => Class['apache::service'],
  }
}