Puppet Class: apache::mod::proxy

Defined in:
manifests/mod/proxy.pp

Summary

Installs and configures `mod_proxy`.

Overview

Parameters:

  • proxy_requests (String) (defaults to: 'Off') —

    Enables forward (standard) proxy requests.

  • allow_from (Optional[Variant[Stdlib::IP::Address, Array[Stdlib::IP::Address]]]) (defaults to: undef) —

    IP address or list of IPs allowed to access proxy.

  • package_name (Optional[String]) (defaults to: undef) —

    Name of the proxy package to install.

  • proxy_via (String) (defaults to: 'On') —

    Set local IP address for outgoing proxy connections.

  • proxy_timeout (Optional[Integer[0]]) (defaults to: undef) —

    Network timeout for proxied requests.

  • proxy_iobuffersize (Optional[String]) (defaults to: undef) —

    Set the size of internal data throughput buffer

See Also:



24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
 
# File 'manifests/mod/proxy.pp', line 24

class apache::mod::proxy (
  String $proxy_requests                    = 'Off',
  Optional[Variant[Stdlib::IP::Address, Array[Stdlib::IP::Address]]] $allow_from = undef,
  Optional[String] $package_name            = undef,
  String $proxy_via                         = 'On',
  Optional[Integer[0]] $proxy_timeout       = undef,
  Optional[String] $proxy_iobuffersize      = undef,
) {
  include apache
  $_proxy_timeout = $apache::timeout
  ::apache::mod { 'proxy':
    package => $package_name,
  }

  $parameters = {
    'proxy_requests'      => $proxy_requests,
    'allow_from'          => $allow_from,
    'proxy_via'           => $proxy_via,
    'proxy_timeout'       => $proxy_timeout,
    'proxy_iobuffersize'  => $proxy_iobuffersize,
  }

  # Template uses $proxy_requests
  file { 'proxy.conf':
    ensure  => file,
    path    => "${apache::mod_dir}/proxy.conf",
    mode    => $apache::file_mode,
    content => epp('apache/mod/proxy.conf.epp', $parameters),
    require => Exec["mkdir ${apache::mod_dir}"],
    before  => File[$apache::mod_dir],
    notify  => Class['apache::service'],
  }
}