Puppet Class: foreman::database

Defined in:
manifests/database.pp

Summary

Set up the foreman database

Overview

Parameters:

  • timeout (Integer[0]) (defaults to: 3600) 


3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
 
# File 'manifests/database.pp', line 3

class foreman::database (
  Integer[0] $timeout = 3600,
) {
  if $foreman::db_manage {
    contain foreman::database::postgresql

    if $foreman::db_manage_rake {
      Class['foreman::database::postgresql'] ~> Foreman::Rake['db:migrate']
    }
  }

  if $foreman::db_manage_rake {
    $seed_env = {
      'SEED_ADMIN_USER'       => $foreman::initial_admin_username,
      'SEED_ADMIN_PASSWORD'   => $foreman::initial_admin_password,
      'SEED_ADMIN_FIRST_NAME' => $foreman::initial_admin_first_name,
      'SEED_ADMIN_LAST_NAME'  => $foreman::initial_admin_last_name,
      'SEED_ADMIN_EMAIL'      => $foreman::initial_admin_email,
      'SEED_ADMIN_LOCALE'     => $foreman::initial_admin_locale,
      'SEED_ADMIN_TIMEZONE'   => $foreman::initial_admin_timezone,
      'SEED_ORGANIZATION'     => $foreman::initial_organization,
      'SEED_LOCATION'         => $foreman::initial_location,
    }

    foreman::rake { 'db:migrate':
      timeout => $timeout,
      unless  => '/usr/sbin/foreman-rake db:abort_if_pending_migrations',
      notify  => Foreman::Rake['db:seed'],
    }
    ~> foreman_config_entry { 'db_pending_seed':
      value => false,
      dry   => true,
    }
    ~> foreman::rake { 'db:seed':
      environment => delete_undef_values($seed_env),
    }
  }
}