Puppet Class: systemd
- Defined in:
- manifests/init.pp
Overview
This module allows triggering systemd commands once for all modules
253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 |
# File 'manifests/init.pp', line 253
class systemd (
Optional[Pattern['^.+\.target$']] $default_target = undef,
Hash[String,String] $accounting = {},
Stdlib::CreateResources $service_limits = {},
Stdlib::CreateResources $networks = {},
Stdlib::CreateResources $timers = {},
Stdlib::CreateResources $tmpfiles = {},
Stdlib::CreateResources $unit_files = {},
Boolean $manage_resolved = false,
Optional[Enum['systemd-resolved']] $resolved_package = undef,
Enum['stopped','running'] $resolved_ensure = 'running',
Optional[Variant[Array[String],String]] $dns = undef,
Optional[Variant[Array[String],String]] $fallback_dns = undef,
Optional[Variant[Array[String],String]] $domains = undef,
Optional[Variant[Boolean,Enum['resolve']]] $llmnr = undef,
Optional[Variant[Boolean,Enum['resolve']]] $multicast_dns = undef,
Optional[Variant[Boolean,Enum['allow-downgrade']]] $dnssec = undef,
Variant[Boolean,Enum['yes', 'opportunistic', 'no']] $dnsovertls = false,
Optional[Variant[Boolean,Enum['no-negative']]] $cache = undef,
Optional[Variant[Boolean,Enum['udp','tcp','absent']]] $dns_stub_listener = undef,
Optional[Variant[Array[String[1]],Enum['absent']]] $dns_stub_listener_extra = undef,
Boolean $manage_resolv_conf = true,
Boolean $use_stub_resolver = false,
Boolean $manage_networkd = false,
Enum['stopped','running'] $networkd_ensure = 'running',
Optional[String[1]] $networkd_package = undef,
Boolean $manage_timesyncd = false,
Enum['stopped','running'] $timesyncd_ensure = 'running',
Optional[String[1]] $timesyncd_package = undef,
Optional[Variant[Array,String]] $ntp_server = undef,
Optional[Variant[Array,String]] $fallback_ntp_server = undef,
Optional[Boolean] $set_local_rtc = undef,
Optional[String[1]] $timezone = undef,
Boolean $manage_accounting = false,
Boolean $purge_dropin_dirs = true,
Boolean $manage_journald = true,
Systemd::JournaldSettings $journald_settings = {},
Boolean $manage_journal_upload = false,
Systemd::JournalUploadSettings $journal_upload_settings = {},
Boolean $manage_journal_remote = false,
Systemd::JournalRemoteSettings $journal_remote_settings = {},
Systemd::MachineInfoSettings $machine_info_settings = {},
Boolean $manage_udevd = false,
Optional[Variant[Integer,String]] $udev_log = undef,
Optional[Integer] $udev_children_max = undef,
Optional[Integer] $udev_exec_delay = undef,
Optional[Integer] $udev_event_timeout = undef,
Optional[Enum['early', 'late', 'never']] $udev_resolve_names = undef,
Optional[Variant[Integer,String]] $udev_timeout_signal = undef,
Boolean $udev_reload = false,
Boolean $manage_logind = false,
Systemd::LogindSettings $logind_settings = {},
Boolean $manage_all_network_files = false,
Stdlib::Absolutepath $network_path = '/etc/systemd/network',
Stdlib::CreateResources $loginctl_users = {},
Stdlib::CreateResources $dropin_files = {},
Stdlib::CreateResources $manage_units = {},
Stdlib::CreateResources $manage_dropins = {},
Stdlib::CreateResources $udev_rules = {},
Boolean $manage_coredump = false,
Boolean $manage_nspawn = false,
Optional[Enum['systemd-container']] $nspawn_package = undef,
Systemd::CoredumpSettings $coredump_settings = {},
Boolean $coredump_backtrace = false,
Boolean $manage_oomd = false,
Optional[String[1]] $oomd_package = undef,
Enum['stopped','running'] $oomd_ensure = 'running',
Systemd::OomdSettings $oomd_settings = {},
Boolean $udev_purge_rules = false,
Boolean $manage_system_conf = false,
Systemd::ServiceManagerSettings $system_settings = {},
Boolean $manage_user_conf = false,
Systemd::ServiceManagerSettings $user_settings = {},
) {
contain systemd::install
if $default_target {
$target = stdlib::shell_escape($default_target)
service { $target:
ensure => 'running',
enable => true,
}
exec { "systemctl set-default ${target}":
command => "systemctl set-default ${target}",
unless => "test $(systemctl get-default) = ${target}",
path => $facts['path'],
}
}
$service_limits.each |$service_limit, $service_limit_data| {
systemd::service_limits { $service_limit:
* => $service_limit_data,
}
}
$networks.each |$network, $network_data| {
systemd::network { $network:
* => $network_data,
}
}
$timers.each |$timer, $timer_data| {
systemd::timer { $timer:
* => $timer_data,
}
}
$tmpfiles.each |$tmpfile, $tmpfile_data| {
systemd::tmpfile { $tmpfile:
* => $tmpfile_data,
}
}
$unit_files.each |$unit_file, $unit_file_data| {
systemd::unit_file { $unit_file:
* => $unit_file_data,
}
}
if $manage_resolved and $facts['systemd_internal_services'] and $facts['systemd_internal_services']['systemd-resolved.service'] {
contain systemd::resolved
Class['systemd::install'] -> Class['systemd::resolved']
}
if $manage_networkd and $facts['systemd_internal_services'] and $facts['systemd_internal_services']['systemd-networkd.service'] {
contain systemd::networkd
Class['systemd::install'] -> Class['systemd::networkd']
}
contain systemd::timedatectl
if $manage_timesyncd and $facts['systemd_internal_services'] and $facts['systemd_internal_services']['systemd-timesyncd.service'] {
contain systemd::timesyncd
}
if $manage_udevd {
contain systemd::udevd
}
# $manage_accounting is retained for backward compatibility
if $manage_accounting or $manage_system_conf or $manage_user_conf {
contain systemd::service_manager
}
unless empty($machine_info_settings) {
contain systemd::machine_info
}
if $manage_journald {
contain systemd::journald
}
if $manage_journal_upload {
contain systemd::journal_upload
}
if $manage_journal_remote {
contain systemd::journal_remote
}
if $manage_logind {
contain systemd::logind
}
if $manage_coredump {
contain systemd::coredump
}
if $manage_oomd {
contain systemd::oomd
}
$dropin_files.each |$name, $resource| {
systemd::dropin_file { $name:
* => $resource,
}
}
$manage_units.each |$name, $resource| {
systemd::manage_unit { $name:
* => $resource,
}
}
$manage_dropins.each |$name, $resource| {
systemd::manage_dropin { $name:
* => $resource,
}
}
}
|